Question

我正在尝试编译下面的Fortran模块（使用gfortran 7.2.0）。关键是定义一个派生类型，该类型又包含来自bspline-fortran库（https://github.com/jacobwilliams/bspline-fortran）的派生类型bspline_3d的两个实例。然后我想定义一个类型绑定过程，该过程将依次调用这两种类型的类型绑定evaluate过程，并将结果作为带有两个元素的数组返回。

当我尝试编译下面的模块时，我收到一条错误消息

     procedure  :: evaluate => evaluate_2d
             1
Error: Non-polymorphic passed-object dummy argument of 'evaluate_2d' at (1)

我完全不了解错误信息。

我设法编译了这里找到的简单示例程序：http://fortranwiki.org/fortran/show/Object-oriented+programming并且据我所知，唯一的区别是在我的情况下，“传递对象”（this）确实本身有派生类型的成员变量（type(bspline_3d) :: fvx, fvy），而这些变量可能包含各种各样的东西。

module interpolator_module

use bspline_module
use parameters, only: WP

implicit none

private
public :: interpolator

type :: interpolator
    type(bspline_3d) :: fvx, fvy
    contains
        private
        procedure  :: evaluate => evaluate_2d
end type interpolator

contains
    function evaluate_2d(this, X, t) result(V)
        implicit none
        ! inputs
        type(interpolator),     intent(inout) :: this
        real(WP), dimension(2), intent(in)    :: X
        real(WP),               intent(in)    :: t
        ! output
        real(WP), dimension(2)                :: V
        ! local variables
        integer                               :: iflag
        integer, parameter                    :: d = 0

        call this%fvx%evaluate(X(1), X(2), t, d, d, d, V(1), iflag)
        call this%fvy%evaluate(X(1), X(2), t, d, d, d, V(2), iflag)
    end function
end module interpolator_module

Answer 1

对于定义类似

的类型绑定过程

type my_type
 contains
  procedure :: proc
end type

类型绑定过程有一个传递的参数。也就是说，

时

type(my_type) my_obj
call my_obj%proc

使用

，对象my_obj在参数列表中。将proc定义为

subroutine proc(me)
  type(my_type) me   ! Not correct
end subroutine

然后call my_obj%proc就像call proc%(my_obj)。¹这是错误消息的“传递对象伪参数”部分。

在上面proc的定义中，传递对象伪参数type(my_type) me是非多态的。您可以在其他地方阅读有关多态的信息，但要回答这个问题：传递对象伪参数可能不是非多态的。它必须是多态的，使用class(my_type) me声明：

subroutine proc(me)
  class(my_type) me   ! Polymorphic, declared type my_type
end subroutine

这意味着可以传递my_type类型或扩展my_type类型的对象。这是Fortran语言的要求。

简而言之：改变你的

type(interpolator),     intent(inout) :: this

到

class(interpolator),     intent(inout) :: this

为了使问题复杂化，例如，旧版本的gfortran在理解多态之前理解了类型绑定过程。这意味着有一些错误使用非多态传递对象的例子。

¹我故意将绑定名称proc与程序名称相同。在问题的上下文中，call my_obj%evaluate(...)就像call evaluate_2d(my_obj, ...)。

Answer 2

传递的伪参数this必须始终是多态的。这意味着必须

 class(interpolator),     intent(inout) :: this

而不是

 type(interpolator),     intent(inout) :: this

这是类型绑定过程的基本要求。否则你不能使用扩展类型（子）的过程。

类型绑定过程给出了关于非多态传递对象伪参数的错误

2 个答案: