如何根据花括号在vim中定义缩进？

Question

我使用https://github.com/cakebaker/scss-syntax.vim在vim上突出显示 SCSS （或 SASS ）文件，这非常适合语法突出显示。但是，该插件没有缩进文件，并且无法编写插件。

我想将缩进设置为：

但是，如果我gg=G，我得到：

我怀疑它不理解基于大括号的嵌套缩进。我尝试了

的所有不同组合

set cindent

set nocindent

set autoindent

set smartindent

并尝试使用Tab key == 4 spaces and auto-indent after curly braces in Vim中的代码，包括

set tabstop=2

set shiftwidth=2

set expandtab

...但嵌套大括号缩进似乎无法正常工作。

我相信我可能想要编写一个自定义缩进文件，而我所需要的只是基于嵌套级别的大括号​​的缩进。我该怎么办呢？如果某人有一个具有类似语法的文件类型的缩进文件，那么这也很好。

Answer 1

这是一个快速入侵，基于内置的perl缩进代码（在indent/perl.vim中）。希望您可以使用它来获得您想要做的事情。有关更多详细信息，请参阅perl缩进代码或缩进​​目录中的另一个文件中的更详细注释。

setlocal indentexpr=GetMyIndent()
function! GetMyIndent()
    let cline = getline(v:lnum)

    " Find a non-blank line above the current line.
    let lnum = prevnonblank(v:lnum - 1)
    " Hit the start of the file, use zero indent.
    if lnum == 0
        return 0
    endif
    let line = getline(lnum)
    let ind = indent(lnum)

    " Indent blocks enclosed by {}, (), or []
    " Find a real opening brace
    let bracepos = match(line, '[(){}\[\]]', matchend(line, '^\s*[)}\]]'))
    while bracepos != -1
        let brace = strpart(line, bracepos, 1)
        if brace == '(' || brace == '{' || brace == '['
            let ind = ind + &sw
        else
            let ind = ind - &sw
        endif
        let bracepos = match(line, '[(){}\[\]]', bracepos + 1)
    endwhile
    let bracepos = matchend(cline, '^\s*[)}\]]')
    if bracepos != -1
        let ind = ind - &sw
    endif

    return ind
endfunction

将该文件保存为~/.vim/indent/something.vim，其中something是您的文件类型（如果您使用的话，请将~/.vim替换为vimfiles的路径。

你可能还想在文件的开头加上这个（但是只有在没有可能首先加载的其他缩进声明时）：

" Only load this indent file when no other was loaded.
if exists("b:did_indent")
    finish
endif
let b:did_indent = 1