Question

使用perl -d调试perl程序时，如何将其限制为仅使用给定的模块集或lib的路径？

Answer 1

DB::cmd_b_sub或DB::break_subroutine函数在任意函数的开头设置断点。您可以遍历存储以查找要传递给此函数的参数集。例如，

sub add_breakpoints_for_module {
    my $module = shift;
    return unless $INC{"perl5db.pl"};    # i.e., unless debugger is on
    no strict 'refs';
    for my $sub (eval "values %" . $module . "::") {
        if (defined &$sub) {          # if the symbol is valid sub name
            DB::cmd_b_sub(substr($sub,1));   # add breakpoint
        }
    }
}

此代码应在加载相关模块后运行。

以下是如何将此想法用作单独的库。将此代码保存到Devel/ModuleBreaker.pm路径上某处的@INC，然后调用调试器

perl -d:ModuleBreaker=Some::Module,Some::Other::Module script_to_debug.pl args

# Devel/ModuleBreaker.pm - automatically break in all subs in arbitrary modules
package Devel::ModuleBreaker;
sub import {
    my ($class,@modules) = @_;
    our @POSTPONE = @modules;
    require "perl5db.pl";
}
CHECK { # expect compile-time mods have been loaded before CHECK phase
    for my $module (our @POSTPONE) {
        no strict 'refs';
        for my $sub (eval "values %" . $module . "::") {
            defined &$sub && DB::cmd_b_sub(substr($sub,1));
        }
    }
}
1;

这里有一个版本可以打破与任意模式相匹配的子程序（这样可以更容易地破坏子模块内部）。它利用了%DB::sub表，它包含有关所有已加载子程序（包括匿名子程序）的信息。

package Devel::SubBreaker;
# install as Devel/SubBreaker.pm on @INC
# usage:  perl -d:SubBreaker=pattern1,pattern2,... script_to_debug.pl args
sub import {
    my $class = shift;
    our @patterns = @_;
    require "perl5db.pl";
}
CHECK {
    foreach my $sub (keys %DB::sub) {
        foreach my $pattern (our @patterns) {
            $sub =~ $pattern and DB::cmd_b_sub($sub), last;
        }
    }
}

如何在给定的模块或lib路径中限制perl调试？

1 个答案: