Question

我正在尝试在我的Groovy脚本中使用多个collectEntries。最好看看代码，现在我有了：

stage('Test') {
            // Reading content of the file
            def portsFileContent = readFile 'UsedPorts.txt'

            // Split the file by next line
            def ports = portsFileContent.split('\n')

            def steps = ports.collectEntries { port ->
                ["UI Test on port $port", {
                    sh "#!/bin/bash -lx \n startServerWithDifferentPort --params=port=$port"
                }]
            }
            parallel steps
        }

在文件“UsedPorts.txt”中，不同的端口按行分隔，如：

4723
4733
4743

因此，这些数字存储在变量ports中，然后使用此变量为每个端口启动服务器实例。因此，在这种情况下，它将通过此命令启动3个不同的serverinstance：

def steps = ports.collectEntries { port ->
                ["UI Test on port $port", {
                    sh "#!/bin/bash -lx \n startServerWithDifferentPort --params=port=$port"
                }]
            }
            parallel steps

由于parallel steps服务器的起始3实例同时具有不同的端口。

多数工作正常，但我有另一个文件，需要再次执行相同操作。所以在我的第二个文件中有以下条目：

name1
name2
name3

我再次创建了一个变量，用于存储我的3个条目：

def anotherFile = readFile 'Names.txt'
def names = anotherFile.split('\n')

这就是我的尝试：

stage('Test') {
            // Reading content of the file
            def portsFileContent = readFile 'UsedPorts.txt'

            // Split the file by next line
            def ports = portsFileContent.split('\n')

            // Do the same again
            def anotherFile = readFile 'Names.txt'
            def names = anotherFile.split('\n')

            def steps = ports.collectEntries, names.collectEntries { port, name ->
                ["UI Test on $name", {
                    sh "#!/bin/bash -lx \n someMoreShellStuff --params=port=$port"
                }]
            }
            parallel steps
        }

但是我不能用逗号分隔我的第二个collectEntries，因为它给我一个语法错误。现在我的问题是，我如何在同一个命令中使用这个变量。它甚至可能吗？

由于

更新＃1

在使用Szymon Stepniak的答案后，我的新代码如下所示：

stage('Test') {
            // Reading content of the file
            def portsFileContent = readFile 'AppiumUsedPorts.txt'

            // Split the file by next line
            def ports = portsFileContent.split('\n')

            // Getting device IDs to get properties of device
            def deviceIDFileContent = readFile 'DeviceIDs.txt'
            def deviceIDs = deviceIDFileContent.split('\n')

            // Define port and id as an pair
            def pairs = (0..Math.min(ports.size(), deviceIDs.size())).collect { i -> [id: deviceIDs[i], port: ports[i]] }

            def steps = pairs.collectEntries { pair ->
                ["UI Test on ${pair.id}", {
                    sh "echo 'Running test with port ${pair.port}'"
                }]
            }
            parallel steps
        }

这导致错误java.lang.ArrayIndexOutOfBoundsException

更新＃2

AppiumUsedPorts.txt的内容：

4723
4733

DeviceIDs.txt

的内容

5353352c
G000KU0663550R92

Answer 1

您希望从两个列表中压缩元素 - ports和names，并在创建并行执行步骤时使用这些对。因此，假设ports和names包含类似的内容：

def ports = [8080, 8081, 8082, 8083]
def names = ['Host A', 'Host B', 'Host C', 'Host D', 'Host E']

你需要一个像这样的对的列表：

def pairs = [[port: 8080, name: 'Host A'], [port: 8081, name: 'Host B'], [port: 8082, name: 'Host C'], [port:8083, 'Host D']]

我故意使用两个不同大小的列表来解释压缩两个列表的结果总是与最短列表相同。

Groovy有一个方法GroovyCollections.transpose(List lists)，它会列出一系列列表（例如[[8080, 8081, 8082, 8083], ['Host A', 'Host B', 'Host C', 'Host D', 'Host E']]）和＆＃34; zips＆＃34;两个列表如：

[[8080, 'Host A'], [8081, 'Host B'], [8082, 'Host C'], [8083, 'Host D']]

但它不适用于Jenkins Pipeline - 如果你尝试使用它，你会得到：

org.jenkinsci.plugins.scriptsecurity.sandbox.RejectedAccessException: Scripts not permitted to use staticMethod org.codehaus.groovy.runtime.DefaultGroovyMethods transpose java.util.List

无论如何，你可以使用{0}到collect范围内的min(ports.size(), names.size())来做同样的事情来创建一个列表那些对/映射。看一下下面的例子：

node {
    stage('Test') {
        def ports = [8080, 8081, 8082, 8083]
        def names = ['Host A', 'Host B', 'Host C', 'Host D', 'Host E']

        def pairs = (0..<Math.min(ports.size(), names.size())).collect { i -> [name: names[i], port: ports[i]] }

        def steps = pairs.collectEntries { pair ->
            ["UI Test on ${pair.name}", {
                sh "echo 'Running test with port ${pair.port}'"
            }]
        }

        parallel steps
    }
}

在这个例子中，我们将两个列表转换为一个映射列表，如[port: ..., name: ...]，我们在该映射列表上调用collectEntries以获得 - port和name在同一个执行步骤中。在Jenkins管道中运行此脚本会产生以下输出：

[Pipeline] {
[Pipeline] stage
[Pipeline] { (Test)
[Pipeline] parallel
[Pipeline] [UI Test on Host A] { (Branch: UI Test on Host A)
[Pipeline] [UI Test on Host B] { (Branch: UI Test on Host B)
[Pipeline] [UI Test on Host C] { (Branch: UI Test on Host C)
[Pipeline] [UI Test on Host D] { (Branch: UI Test on Host D)
[Pipeline] [UI Test on Host A] sh
[UI Test on Host A] [test-pipeline] Running shell script
[Pipeline] [UI Test on Host B] sh
[UI Test on Host B] [test-pipeline] Running shell script
[Pipeline] [UI Test on Host C] sh
[UI Test on Host C] [test-pipeline] Running shell script
[Pipeline] [UI Test on Host D] sh
[UI Test on Host A] + echo Running test with port 8080
[UI Test on Host A] Running test with port 8080
[UI Test on Host B] + echo Running test with port 8081
[UI Test on Host B] Running test with port 8081
[UI Test on Host D] [test-pipeline] Running shell script
[Pipeline] [UI Test on Host A] }
[UI Test on Host C] + echo Running test with port 8082
[UI Test on Host C] Running test with port 8082
[UI Test on Host D] + echo Running test with port 8083
[UI Test on Host D] Running test with port 8083
[Pipeline] [UI Test on Host B] }
[Pipeline] [UI Test on Host C] }
[Pipeline] [UI Test on Host D] }
[Pipeline] // parallel
[Pipeline] }
[Pipeline] // stage
[Pipeline] }
[Pipeline] // node
[Pipeline] End of Pipeline
Finished: SUCCESS

希望它有所帮助。

在Groovy和Jenkins管道中组合多个collectEntries

1 个答案: