在Haskell中生成无限列表[0,1，-1,2，-2，...

Question

假设我们想在Haskell中生成列表[0, 1, -1, 2, -2, ...。

实现这一目标的最优雅方式是什么？

我提出了这个解决方案：

solution = [0] ++ foldr (\(a,b) c->a:b:c) [] zip [1..] $ map negate [1..]

但我相信一定有更好的方法。

Answer 1

这似乎是为了理解而做的事情：

solution = 0 : [y | x <- [1..], y <- [x, -x]]

Answer 2

使用iterate

也许更优雅的方法是使用iterate :: (a -> a) -> a -> [a]和每次生成下一个项目的函数。例如：

solution = iterate nxt 0
    where nxt i | i > 0 = -i
                | otherwise = 1-i

或者我们可以使用if - then - else内嵌此内容：

solution = iterate (\i -> if i > 0 then -i else 1-i) 0

或者我们可以使用fromEnum将布尔值转换为整数，就像@melpomene所说的那样，然后使用它将1或0添加到答案中，所以：

solution = iterate (\i -> fromEnum (i < 1)-i) 0

哪个更自由点：

import Control.Monad(ap)

solution = iterate (ap subtract (fromEnum . (< 1))) 0

使用(<**>)

我们还可以使用应用中的<**>运算符来生成每次数字的正负变量，例如：

import Control.Applicative((<**>))

solution = 0 : ([1..] <**> [id, negate])

Answer 3

怎么样

concat (zipWith (\x y -> [x, y]) [0, -1 ..] [1 ..])

或

concat (transpose [[0, -1 ..], [1 ..]])

Answer 4

怎么样：

tail $ [0..] >>= \x -> [x, -x]

在片刻的反思中，我认为使用nub代替tail会更优雅。

Answer 5

另一种原始解决方案

alt = 0 : go 1
  where go n = n : -n : go (n+1)

Answer 6

您也可以在此处使用concatMap代替foldr，并将map negate [1..]替换为[0, -1..]：

solution = concatMap (\(a, b) -> [a, b]) $ zip [0, -1..] [1..]

如果您想使用negate，那么这是另一种选择：

solution = concatMap (\(a, b) -> [a, b]) $ (zip . map negate) [0, 1..] [1..]

Answer 7

仅仅因为没人说：

0 : concatMap (\x -> [x,-x]) [1..]

Answer 8

参加派对的时间较晚，但这样做也是如此

solution = [ (1 - 2 * (n `mod` 2)) * (n `div` 2) | n <- [1 .. ] ]