Question

我正在尝试比较两个YAML文件，如下所示

忽略所有注释行
如果文件具有相同的模块，则比较这些模块的版本
如果版本不同，则将差异打印到文件output.log并引发错误

file1.yml

Modules:
     python:
         PATH: /cfg/python/version-1.0
     c:
         PATH: /cfg/c/release-1.2.0
     c++:
         PATH: /cfg/c++/release-1.1.5
     java:
         PATH: /cfg/java/version-2.157
     #connect:
     #    PATH: /cfg/connect/release-1.2.3

file2.yml

Modules:
     python:
         PATH: /cfg/python/version-1.1
     c:
         PATH: /cfg/c/release-1.2.0
     java:
         PATH: /cfg/java/version-2.161
     eclipse:
         PATH: /cfg/eclipse/version-4.5
     #connect:
     #    PATH: /cfg/connect/release-1.2.0

期望的输出

Error:
  File1.yml - python: PATH: /cfg/python/verison-1.0
  file2.yml - python: PATH: /cfg/python/verison-1.1
Error:
  file1.yml - java: PATH: /cfg/java/version-2.157
  file2.yml - java: PATH: /cfg/java/version-2.161

我的代码

use strict;
use warnings;

open f1, "file1.yml" or die "couldn't open the file: $! \n ";
my @line1 = <f1>;
close(f1);

open f2, "file2.yml" or die "couldn't open the file: $! \n ";
my @line2 = <f2>;
close(f2);

open( OUT, ">", "error.txt" );

for ( my $i = 0; $i < @line1; $i++ ) {

    for ( my $j = 0; $j < @line2; $j++ ) {

        if ( $line1[$i] =~ $line2[$j] ) {
            print OUT "Match Found: \n $line1[$i] \n $line2[$j]";
        }
    }
}
close OUT;

输出

Match Found:
    Modules:
    Modules:
 Match Found:
    python:
    python:
 Match Found:
    c:
    c: 
 Match Found:
    java:
    java:
 Match Found:
    #connect:
    #connect:

Answer 1

从技术上讲，你的程序没有任何问题，所以我不会提供修复或解释。您编写的代码与您尝试解决的代码不同。

相反，我将逐步向您展示一种不同的方法。首先，请记住YAML是一种数据结构描述。您可以将其读入Perl并将其转换为Perl可以理解的本机数据结构，而不是使用文本比较。你的文件都有类似的结构，这很简单。

阅读数据结构并将其转换为其他格式很难。幸运的是，Perl的许多优势之一就是已经解决了很多问题，并且可以在CPAN上使用。

use strict;
use warnings;
use YAML 'LoadFile';

my $file1 = LoadFile('file1.yml');
my $file2 = LoadFile('file2.yml');

该程序将读取您的两个文件，并使用LoadFile from the YAML module将YAML数据结构内部转换为Perl哈希引用。

就其本身而言当然不是很有用。所以，让我们检查这些结构是什么样的。 Data::Dumper对此非常有用，它随您的Perl安装一起提供。（我个人会使用Data::Printer，因为我认为输出更具可读性，但这取决于你。）

use Data::Dumper;

print Dumper $file1;
print Dumper $file2;

这将告诉我们：

$VAR1 = {
          'Modules' => {
                       'java' => {
                                 'PATH' => '/cfg/java/version-2.157'
                               },
                       'c' => {
                              'PATH' => '/cfg/c/release-1.2.0'
                            },
                       'c++' => {
                                'PATH' => '/cfg/c++/release-1.1.5'
                              },
                       'python' => {
                                   'PATH' => '/cfg/python/verison-1.0'
                                 }
                     }
        };
$VAR1 = {
          'Modules' => {
                       'c' => {
                              'PATH' => '/cfg/c/release-1.2.0'
                            },
                       'java' => {
                                 'PATH' => '/cfg/java/version-2.161'
                               },
                       'python' => {
                                   'PATH' => '/cfg/python/verison-1.1'
                                 },
                       'eclipse' => {
                                    'PATH' => '/cfg/eclipse/version-4.5'
                                  }
                     }
        };

注意密钥的顺序与文件中的顺序不同。这是因为Perl中的哈希值无序。这是一个功能。为了获得始终如一的输出，我们稍后需要sort这些键。

因此我们看到两个结构都有一个键 Modules 。在内部，还有另一个哈希引用，它将语言作为键，并且在每个哈希引用中，还有另一个哈希引用，其中只有一个 PATH 键和一个值。我们对每种语言的每个 PATH 的价值感兴趣。

要获取语言，我们会迭代两个文件之一的 Modules 的keys。然后我们可以将这些值一直比较下来。如果它们是not equal，我们会打印错误消息。

use v5.10; # to get say

# get shortcuts so the lines are not as long
my $modules1 = $file1->{Modules};
my $modules2 = $file2->{Modules};
foreach my $language (sort keys %{ $file1->{Modules} }) {
    if ($modules1->{$language}->{PATH} ne $modules2->{$language}->{PATH} ) {
        say "Error:";
        say "file1.yml - $language: PATH: $modules1->{$language}->{PATH}";
        say "file2.yml - $language: PATH: $modules2->{$language}->{PATH}";
    }
}

我使用的是say而不是print，它为我们添加了换行符。其他变量$modules1和$modules2只是为了让代码更易于阅读，因为$file1->{Modules}->{$language}->{PATH}很长。

现在，如果我们运行我们的程序，我们将获得以下输出。

Error:
file1.yml - c++: PATH: /cfg/c++/release-1.1.5
file2.yml - c++: PATH: 
Error:
file1.yml - java: PATH: /cfg/java/version-2.157
file2.yml - java: PATH: /cfg/java/version-2.161
Error:
file1.yml - python: PATH: /cfg/python/verison-1.0
file2.yml - python: PATH: /cfg/python/verison-1.1
Use of uninitialized value in string ne at /home/simbabque/code/scratch/scratch.pl line 133.
Use of uninitialized value in concatenation (.) or string at /home/simbabque/code/scratch/scratch.pl line 136.

这几乎是我们想要的，但是有一些令人讨厌的警告（因为我们已经打开use warnings），并且 c ++ 没有任何价值。我们需要过滤掉仅存在于两个文件之一中的语言。

仅存在于 file2.yml 中的语言已被考虑，因为我们只查看 file1.yml 中的键。要删除第一个文件中的文件，我们必须在访问之前检查他们是否exist。

next unless exists $modules2->{$language};

unless keyword与if (not ...)类似，我认为它更容易阅读，尤其是在这个非常简洁的post-fix notation中。现在程序给出了预期的输出。

Error:
file1.yml - java: PATH: /cfg/java/version-2.157
file2.yml - java: PATH: /cfg/java/version-2.161
Error:
file1.yml - python: PATH: /cfg/python/verison-1.0
file2.yml - python: PATH: /cfg/python/verison-1.1

这是整件事。不要忘记从代码中删除Data :: Dumper，因为它在生产程序中无关。我们仅将其用作调试助手。

use strict;
use warnings;
use YAML 'LoadFile';

my $file1 = LoadFile('file1.yml');
my $file2 = LoadFile('file2.yml');

use v5.10;

# get shortcuts so the lines are not as long
my $modules1 = $file1->{Modules};
my $modules2 = $file2->{Modules};
foreach my $language (sort keys %{ $file1->{Modules} }) {
    next unless exists $modules2->{$language};
    if ($modules1->{$language}->{PATH} ne $modules2->{$language}->{PATH} ) {
        say "Error:";
        say "file1.yml - $language: PATH: $modules1->{$language}->{PATH}";
        say "file2.yml - $language: PATH: $modules2->{$language}->{PATH}";
    }
}

读取两个YAML文件并比较两者中出现的模块

file1.yml

file2.yml

期望的输出

我的代码

输出

1 个答案: