Question

我想知道如果符合某些条件，如何使用XSLT将节点向上移动一级。举个例子来看看下面的XML源：

<Settings>
  <String [...]>
    <Boolean [...]/>
  </String>
</Settings>

这是我作为起始情况的XML。需要说明的是，节点名称“Settings”，“String”，“Boolean”是我们定义的特殊节点。

问题是“字符串”节点内不允许使用“布尔”节点。这就是为什么我必须在升级上移动那些“布尔”节点。所需的XML如下所示：

<Settings>
  <String [...]></String>
  <Boolean [...]/>
</Settings>

XSLT还必须处理每个具有兄弟布尔节点的String节点，而不管XML树中的位置如何。

到目前为止，我了解到您必须首先使用“身份规则”复制所有XML，然后对所需的转换应用一些特殊规则：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"        
  xmlns:fo="http://www.w3.org/1999/XSL/Format" 
  xmlns:xs="http://www.w3.org/2001/XMLSchema" 
  xmlns:fn="http://www.w3.org/2005/xpath-functions">

  <!-- Identity rule -->
  <xsl:template match="node() | @*">
    <xsl:copy>
      <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
  </xsl:template>

  <!-- special rules ... -->

</xsl:stylesheet>

我正在努力解决的问题是将所有“布尔”节点移动到“String”节点的兄弟节点的规则。我怎么能这样做？！

Answer 1

我对要求的解释给出了解决方案

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>

<xsl:template match="node() | @*">
    <xsl:copy>
        <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="String">
    <xsl:copy>
        <xsl:apply-templates select="child::node()[not(self::Boolean)]"/>
    </xsl:copy>
    <xsl:apply-templates select="Boolean"/>
</xsl:template>

</xsl:stylesheet>

Answer 2

尝试以下方法：

<!-- copy all -->
<xsl:template match="*">
    <xsl:copy>
        <xsl:copy-of select="@*" />
        <xsl:apply-templates />
    </xsl:copy>
</xsl:template>

<!-- ignore booleans-inside-strings -->
<xsl:template match="String/Boolean" />

<!-- place the booleans-inside-strings into the settings element -->
<xsl:template match="Settings">
    <xsl:copy>
        <xsl:copy-of select="//String/Boolean" />
        <xsl:apply-templates />
    </xsl:copy>
</xsl:template>

Answer 3

这个解决方案与@ Michae-Kay非常相似。但是，身份规则的覆盖更精确一些 - 只有String个真正拥有Boolean子元素的元素匹配：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="String[Boolean]">
  <xsl:copy>
    <xsl:apply-templates select="node()[not(self::Boolean)]|@*"/>
  </xsl:copy>
  <xsl:apply-templates select="Boolean"/>
 </xsl:template>
</xsl:stylesheet>

对以下XML文档应用此转换时：

<Settings>
    <String>
        <Boolean />
    </String>
    <String/>
</Settings>

产生了想要的正确结果：

<Settings>
   <String/>
   <Boolean/>
   <String/>
</Settings>

XSLT：将节点向上移动一级

3 个答案: