Question

我总是得到

PLS-00597: expression 'V_EMP_REC' in the INTO list is of wrong type

这是包，我正在使用默认的HR模式

CREATE OR REPLACE PACKAGE EMP_PKG AS
  TYPE T_EMP_REC IS RECORD (
    V_EMP_TAB EMPLOYEES%ROWTYPE,
    V_DEPT_NAME DEPARTMENTS.DEPARTMENT_NAME%TYPE
  );

  FUNCTION GET_EMP (P_EMP_ID EMPLOYEES.EMPLOYEE_ID%TYPE) RETURN T_EMP_REC;
END EMP_PKG;
/
CREATE OR REPLACE PACKAGE BODY EMP_PKG AS
  FUNCTION GET_EMP (P_EMP_ID EMPLOYEES.EMPLOYEE_ID%TYPE)
  RETURN T_EMP_REC
  AS
    CURSOR V_EMP_CUR IS
      SELECT E.*, D.DEPARTMENT_NAME
      FROM EMPLOYEES E, DEPARTMENTS D
      WHERE E.EMPLOYEE_ID = P_EMP_ID
      AND E.DEPARTMENT_ID = D.DEPARTMENT_ID;

  V_EMP_REC T_EMP_REC;
  BEGIN
    OPEN V_EMP_CUR;
    FETCH V_EMP_CUR INTO V_EMP_REC;
    CLOSE V_EMP_CUR;

  RETURN V_EMP_REC; 
  END GET_EMP;
END EMP_PKG;

列数匹配，我总是使用与表相同的类型。我不知道这种方法是否可行，而不是声明记录类型中的每一列。

Answer 1

您必须在集合中明确声明employees和departments的所有列：

TYPE t_emp_rec IS RECORD (employees_col1 employees.employees_col1%TYPE,
                          employees_col2 employees.employees_col2%TYPE,
                          ...
                          departments_col1 departments.departments_col1%TYPE,
                          departments_col2 departments.departments_col2%TYPE
                          ...
                          );

在您的代码中，您会收到错误，因为您正在尝试将列类型（NUMBER，VARCHAR2，DATE，...）分配给RECORD集合。

Answer 2

正如Guillaume建议的那样，明确提到了列名。当您调用该函数时，您会收到T_EMP_REC记录。现在每个变量都可以作为T_EMP_REC.employees_col1，T_EMP_REC.employees_col2，T_EMP_REC.department_col1等进行访问。

可以回复你对他的答案的评论，所以这样回答。

Answer 3

作为替代方案，如果您只希望记录类型为平面结构并与光标匹配，则可以将光标放在包规范中并将类型定义为cursor%rowtype：

create or replace package emp_pkg
as
    cursor emp_cur
        ( cp_emp_id employees.employee_id%type )
    is
        select e.*, d.department_name
        from   employees e
               join departments d
                    on  e.department_id = d.department_id
        where  e.employee_id = cp_emp_id;

    subtype t_emp_rec is emp_cur%rowtype;

    function get_emp
        ( p_emp_id employees.employee_id%type )
        return t_emp_rec;

end emp_pkg;


create or replace package body emp_pkg
as
    function get_emp
        ( p_emp_id employees.employee_id%type )
        return t_emp_rec
    is
        v_emp_rec t_emp_rec;
    begin
        open emp_cur(p_emp_id);
        fetch emp_cur into v_emp_rec;
        close emp_cur;

        return v_emp_rec;
    end get_emp;
end emp_pkg;

是否可以使用rowtype将光标提取到记录中？

3 个答案: