Question

该程序从命令行中指定的目录中读取文件列表，创建一个哈希数组，其中每个文件都有密钥路径，大小和sha256sum。

我正在尝试创建一个文件的gzip压缩包，其中每个文件都是名称，校验和附加了文件的原始扩展名。

我成功创建了一个压缩文件的tarball。但是，当我尝试使用Archive :: Tar的重命名方法时，我遇到了这个错误：

档案中没有这样的文件：'/ path / to / file1.txt'位于./program.pl第62行。档案中的每个文件都会重复此错误。

use strict;
use warnings;
use Data::Dumper qw(Dumper);
use File::Spec qw(catfile rel2abs);
use Digest::SHA qw(sha256_hex);
use Archive::Tar;
use Archive::Tar::File;

my $dir = $ARGV[0];
my $url = $ARGV[1];
my @AoH;
my @checksumfiles;
my $tar = Archive::Tar->new;
my $archive = "archive.tar.gz";

opendir DIR, $dir or die "cannot open dir $dir: $!\n";
chdir $dir or die "cannot navigate to dir $dir: $!\n";

while(my $file = readdir DIR) {
    next unless(-f File::Spec->catfile($dir, $file));
    next if($file =~ m/^\./);

    my $fullpath = File::Spec->rel2abs($file);
    my $fullsize = -s File::Spec->catfile($dir, $file);
    my $fullid   = sha256_hex($fullpath);

    my %hash = (
        path    =>  $fullpath,
        size    =>  $fullsize,
        id      =>  $fullid,
    );

    push(@AoH, \%hash);
}
my @array;
for my $i(0..$#AoH) {
    no warnings 'uninitialized';
    my ($ext) = $AoH[$i]{path} =~ (/(\.[^.]+)$/);
    my $idext = $AoH[$i]{id} . $ext;
    push(@checksumfiles, $idext);
    push(@array, $AoH[$i]{path});
}

Archive::Tar->create_archive($archive, COMPRESS_GZIP, @array);
#print Archive::Tar->list_archive($archive, COMPRESS_GZIP), "\n";

for my $i(0..$#array) {
    $tar->rename($array[$i], $checksumfiles[$i]);
}

print Dumper sort \@array;
print Dumper sort \@checksumfiles;
#print Dumper sort \@AoH;

Answer 1

使用类方法 create_archive创建存档，而在对象上调用rename方法（我的重点）

将内存中存档的文件重命名为$ new_name。

唉，由于该对象从未用于写入/读取存档，因此没有内存存档。

通常，您可以从磁盘读取存档到内存中，从中获取Archive::Tar::File个对象。然后重命名文件并写出新的存档。

my @file_objs = $tar->read($archive);

for my $i (0..$#file_objs) {
    $file_objs[$i]->rename($checksumfiles[$i]);
}
$tar->write('RENAMED_' . $archive, COMPRESS_GZIP);

这在我的测试中有效。

但如果您确实是第一次创建存档，并且需要额外的写入和读取，那么这非常浪费。使用add_files

在内存中构建存档的合适方法

# In a sub to make sure that renaming stays in order in which files are added
sub archive_renamed {
    my ($archive_name, $orig, $new) = @_;
    if (@$orig != @$new) {
        warn "Unequal length of filename lists";
        return;
    }
    my $tar = Archive::Tar->new;

    for my $file (@$orig) {
        if (not $tar->add_files($file)) {
            warn "Error adding $file: ", $tar->error;             
            return;
        }
    }
    my @file_objs = $tar->get_files;

    for my $i (0..$#file_objs) {
        $file_objs[$i]->rename($new->[$i]);
    }

    $tar->write($archive_name, COMPRESS_GZIP);
    if (my $error = $tar->error) {
        warn "Error writing $archive_name: $error";
        return;
    }
    return 1;
}

archive_renamed('RENAMED_'.$archive, \@array, \@checksumfiles);

文件的重命名顺序与添加的顺序相同，因此必须确实添加了所有文件，否则我们最终会使用错误的名称。因此，我们在添加文件时中止任何错误。这就是为什么它也需要在sub中，以便更改不会滑入，以便最终重命名文件。

如果最终在模块中使用Carp :: carp而不是warn。如果主要代码不应该继续出错，请使用die（或模块中的Carp::croak）。

如果此方法的文档中提到的特定属性存在问题（它们不应该），您甚至可以首先使用新名称复制文件并使用这些文件形成存档（然后删除它们）。这也是额外的工作，但比额外的档案阅读和写作无比高效。

重命名文件时，在存档中找不到文件

1 个答案: