Question

以下代码尝试执行某些工作并在出现错误时重试。还有一个错误回调，它调用一个将错误记录到控制台的函数。

执行时，错误仅记录到控制台一次，当程序暂停时，主线程在retryErrorForever中被阻止，并且在获得log时工作线程被阻止。

但为什么？

module Program

type MyLogger(loggerName: string) =
    member __.Warn fmt =
        Printf.kprintf (printfn "%s: %s" loggerName) fmt

let log = MyLogger("Logger")

let retryErrorForever errorCallback retryTimeout work =
    let rec loop () = async {
        let! result = work

        match result with
        | Error e ->
            errorCallback e
            do! Async.Sleep retryTimeout
            return! loop()
        | Ok x -> return Ok x
    }

    loop ()

let retryWorkUntilOk logError timeout (work: unit -> Result<string, string>) =
    let workflow = async {
        return work ()
    }

    let result =
        retryErrorForever logError timeout workflow
        |> Async.RunSynchronously

    match result with
    | Ok x -> x
    | Error e -> failwith <| sprintf "Cannot doWork: %s" e

let logError error =
    log.Warn "%s" error

let doWork work =
    retryWorkUntilOk logError 1000 work

let errorOnly () : Result<string, string> =
    Error "You have no power here"

let result = doWork errorOnly

[<EntryPoint>]
let main _ =
    printfn "%A" result
    0

Answer 1

当在互动中运行时，这个程序正是它应该做的事情：打印＆＃34;你这里没有权力＆＃34;永远的每一秒。

但是，如果您正在编译并运行可执行文件，则存在一个问题：在let result = ...运行之前，在程序集初始化时评估行main，以及整个程序内容在那段时间执行。但是，程序集初始化应该是同步的。它可以启动异步任务，但是在静态初始化完成之前它们将无法完成 - 以及编写程序的方式，静态初始化正在等待那些异步任务完成。所以你陷入了僵局。

要解决此问题，只需使整个事件从main运行，而不是在静态初始化期间运行。这可以通过将result作为一个函数，然后从main调用它来完成：

let result() = doWork errorOnly

[<EntryPoint>]
let main _ =
    printfn "%A" <| result()
    0

从异步方法访问logger对象时的死锁同步运行

1 个答案: