Question

我是JS程序员，试图编写一些Groovy代码（根本没有Java背景）。我需要使用Groovy编写一些模板，所以我创建了一个函数以避免重复。我的目标是能够将html对象传递给函数（例如：p()，div()，span()等等，但是我的工作并不像我预期的那样：

功能

void addon ( addonType, mainHolder, content ) {
  div( class: "addon " + addonType ) {
    div( class: "addon-main" ) {
      div( class: "addon-main-holder" ) {
        yieldUnescaped mainHolder
      }
    }

    div( class: "addon-content" ) {
        yieldUnescaped content
    }
  }
}

不起作用：

[...]
  body {
    addon( 'addon-warning', p('Lorem Ipsum'), p('Dolor sit amet consectetur') )
  }
[...]

作品：

[...]
  body {
    addon( 'addon-warning', '<p>Lorem Ipsum</p>', '<p>Dolor sit amet consectetur</p>') )
  }
[...]

我使用yield而非yieldUnescaped尝试了一些变体，但没有成功。可能吗？任何帮助将不胜感激。

Answer 1

假设您想要将更多基于DSL的标记传递到addon函数中，我会将闭包传递给该函数。这是一个简化的自包含版本（这使得它更难以阅读，因为模板在字符串中;请查看XXX注释）：

import groovy.text.markup.*

def config = new TemplateConfiguration()
def engine = new MarkupTemplateEngine(config)
def template = engine.createTemplate('''
html {
    body {
        addon("Hello World", { // XXX: pass a closure
            p("Lorem Ipsum")
            p("Lorem Ipsum")
            p("Lorem Ipsum")
        })
    }
}

void addon(title, content) {
    h1(title)
    div {
        content() // XXX call the closure
    }
}
''')
Writable output = template.make([:])
println output
// => <html><body><h1>Hello World</h1><div><p>Lorem Ipsum</p><p>Lorem Ipsum</p><p>Lorem Ipsum</p></div></body></html>

Groovy TemplateEngine - 用于标记创建的函数

1 个答案: