Question

我正在寻找内置函数，如下面的pfilter-by-keys：

(pfilter-by-keys '(:a :b) '(:c 10 :b 20 :a 4))
;; => (:B 20 :A 4)

它的代码非常简单：

(defun pfilter-by-keys (keys plist)
  "List -> PList -> PList
  Returns a new plist with only the keys/values correspondent to the given
  keys."
  (loop for (k v) on plist by #'cddr
        when (member k keys :test #'equal)
          append (list k v)))

CL是否有一些像上面那样的内置函数？

PS。：Alexandria功能非常接近：remove-from-plist。

Answer 1

CL:GET-PROPERTIES是一个构建基块：

(defun keep-properties (plist indicator-list &aux k v)
  "Keeps all property list entries for a given indicator-list."
  (loop do (setf (values k v plist)
                 (get-properties plist indicator-list))
        while plist
        collect k collect v
        do (pop plist) (pop plist)))

请注意，最好是收集两次，而不是在LOOP中附加/列表。

Answer 2

没有这样做的功能（这不是人们通常想做的事情）

有一个宏remf可以从某个地方的plist中删除一个键。

您可能实现此目标的另一种方法是：

(destructuring-bind (&key (a nil ap) (b nil bp) &allow-other-keys) plist
  (append (if ap (list :a a)) (if bp (list :b b))))

但请注意，这只有在您已经知道要保留哪些键时才有效，并且这不会保留plist中的顺序，并且不会保留重复的键（即，如果您的plist包含键:a多个结果只会包含一次）。

您可以使用普通（符号）键的普通lambda列表语法对非关键字键进行修改。

Common Lisp - 是否有内置函数来按键过滤plist？

2 个答案: