如何实现not_all_equal/1谓词，如果给定列表包含至少2个不同的元素，则成功，否则失败？
这是我的尝试（不是很纯粹）：
not_all_equal(L) :-
( member(H1, L), member(H2, L), H1 \= H2 -> true
; list_to_set(L, S),
not_all_equal_(S)
).
not_all_equal_([H|T]) :-
( member(H1, T), dif(H, H1)
; not_all_equal_(T)
).
然而，这并不总是最好的行为：
?- not_all_equal([A,B,C]), A = a, B = b.
A = a,
B = b ;
A = a,
B = b,
dif(a, C) ;
A = a,
B = b,
dif(b, C) ;
false.
在这个例子中，只有第一个答案应该出来，另外两个答案是多余的。
答案 0 :(得分：5)
以下是SICStus | SWI使用library(reif)的部分实现。这肯定是正确的，因为当它无法继续时会产生错误。但它缺乏我们想要的普遍性。
not_all_equalp([A,B]) :-
dif(A,B).
not_all_equalp([A,B,C]) :-
if_(( dif(A,B) ; dif(A,C) ; dif(B,C) ), true, false ).
not_all_equalp([A,B,C,D]) :-
if_(( dif(A,B) ; dif(A,C) ; dif(A,D) ; dif(B,C) ; dif(B,D) ), true, false ).
not_all_equalp([_,_,_,_,_|_]) :-
throw(error(representation_error(reified_disjunction),'C\'est trop !')).
?- not_all_equalp(L).
L = [_A,_B], dif(_A,_B)
; L = [_A,_A,_B], dif(_A,_B)
; L = [_A,_B,_C], dif(_A,_B)
; L = [_A,_A,_A,_B], dif(_A,_B)
; L = [_A,_A,_B,_C], dif(_A,_B)
; L = [_A,_B,_C,_D], dif(_A,_B)
;
! error(representation_error(reified_disjunction),'C\'est trop !')
?- not_all_equalp([A,B,C]), A = a, B = b.
A = a,
B = b
; false.
编辑：现在我意识到我根本不需要添加许多dif/2目标！ 一个变量与第一个变量不同就足够了！不需要互相排斥！我仍然感到有点不安全，无法删除dif(B,C)目标...
not_all_equalp([A,B]) :-
dif(A,B).
not_all_equalp([A,B,C]) :-
if_(( dif(A,B) ; dif(A,C) ), true, false ).
not_all_equalp([A,B,C,D]) :-
if_(( dif(A,B) ; dif(A,C) ; dif(A,D) ), true, false ).
not_all_equalp([_,_,_,_,_|_]) :-
throw(error(representation_error(reified_disjunction),'C\'est trop !')).
答案完全相同......我想，这里发生了什么。这个版本是否较弱，不太一致？
答案 1 :(得分：4)
这是一种直截了当的方法，您可以保留logical-purity！
not_all_equal([E|Es]) :-
some_dif(Es, E).
some_dif([X|Xs], E) :-
( dif(X, E)
; X = E, some_dif(Xs, E)
).
以下是使用SWI-Prolog 7.7.2的一些示例查询。
首先，最常见的查询：
?- not_all_equal(Es).
dif(_A,_B), Es = [_A,_B|_C]
; dif(_A,_B), Es = [_A,_A,_B|_C]
; dif(_A,_B), Es = [_A,_A,_A,_B|_C]
; dif(_A,_B), Es = [_A,_A,_A,_A,_B|_C]
; dif(_A,_B), Es = [_A,_A,_A,_A,_A,_B|_C]
...
接下来，OP在问题中提出的查询：
?- not_all_equal([A,B,C]), A=a, B=b.
A = a, B = b
; false. % <- the toplevel hints at non-determinism
最后，我们先将子目标A=a, B=b放在：
?- A=a, B=b, not_all_equal([A,B,C]).
A = a, B = b
; false. % <- (non-deterministic, like above)
很好，但理想情况下，最后一个查询应该确定性地成功！
library(reif) First argument indexing 将第一个谓词参数的主要函子（加上一些简单的内置测试）考虑在内，以改善充分实例化目标的确定性。
这本身就不会 覆盖dif/2令人满意。
我们能做什么？与...合作
reified term equality/inequality - 有效indexing dif/2！
some_dif([X|Xs], E) :- % some_dif([X|Xs], E) :-
if_(dif(X,E), true, % ( dif(X,E), true
(X = E, some_dif(Xs,E)) % ; X = E, some_dif(Xs,E)
). % ).
注意新旧实施的相似之处！
上面，目标X = E在左侧是多余的。我们把它删除吧！
some_dif([X|Xs], E) :-
if_(dif(X,E), true, some_dif(Xs,E)).
甜蜜！但是，唉，我们还没完成（还）！
?- not_all_equal(Xs). DOES NOT TERMINATE
发生了什么事？
事实证明dif/3的实现阻止我们为最常见的查询获得一个很好的答案序列。要做到这一点 - 不使用其他目标强制公平枚举 - 我们需要调整dif/3的实现，我称之为diffirst/3：
diffirst(X, Y, T) :-
( X == Y -> T = false
; X \= Y -> T = true
; T = true, dif(X, Y)
; T = false, X = Y
).
我们在谓词diffirst/3的定义中使用dif/3代替some_dif/2：
some_dif([X|Xs], E) :-
if_(diffirst(X,E), true, some_dif(Xs,E)).
所以，最后，以上是使用新some_dif/2：
?- not_all_equal(Es). % query #1
dif(_A,_B), Es = [_A,_B|_C]
; dif(_A,_B), Es = [_A,_A,_B|_C]
; dif(_A,_B), Es = [_A,_A,_A,_B|_C]
...
?- not_all_equal([A,B,C]), A=a, B=b. % query #2
A = a, B = b
; false.
?- A=a, B=b, not_all_equal([A,B,C]). % query #3
A = a, B = b.
查询＃1没有终止，但具有相同的紧凑答案序列。 不可！
查询＃2仍然是非确定性的。好的。对我而言，这是最好的。
查询＃3已成确定性：现在更好！
底线：
library(reif)来驯服过多的非确定性，同时保持逻辑纯度！diffirst/3应该进入library(reif)：）编辑：使用meta-predicate更为一般（评论建议; thx！）
让我们如此概括some_dif/2：
:- meta_predicate some(2,?).
some(P_2, [X|Xs]) :-
if_(call(P_2,X), true, some(P_2,Xs)).
some/2可以与diffirst/3以外的其他谓词一起使用。
此处not_all_equal/1的更新现在使用some/2代替some_dif/2：
not_all_equal([X|Xs]) :-
some(diffirst(X), Xs).
上面的示例查询仍然给出相同的答案，所以我不会在这里显示。