Question

我有这样的XML：

<countries>
        <country name="Austria" population="8023244" area="83850">
            <city>
                <name>Vienna</name>
                <population>1583000</population>
            </city>
        </country>
        <country name="Spain" population="39181112" area="504750">
            <city>
                <name>Madrid</name>
                <population>3041101</population>
            </city>
        </country>
       [...]
</countries>

我需要一个xQuery表达式来获取人口最多的城市的名称，但我不知道该怎么做。一些想法？

Answer 1

那么，选择city元素，选择最大人口，然后选择具有该人口的城市：

let $cities := //city,
      $max-pob := max($cities/population)
return $cities[population = $max-pob]/name

或排序并采取第一个：

(for $city in //city
order by $city/population descending
return $city)[1]/name

您也可以使用sort功能：

sort(//city, (), function($c) { xs:decimal($c/population) })[last()]/name

Answer 2

XQuery 1.0中的传统方式是

let $p := max(//population) 
return //city[population = $p]/name

但这有两次扫描数据的缺点。

您可以使用高阶函数来避免这种情况，例如：例如：在D4.6.1（https://www.w3.org/TR/xpath-functions-31/#highest-lowest）规范中作为示例显示的最高（）函数或折叠操作：

let $top := fold-left(//city, head(//city), 
    function($top, $this) {
      if (number($this/population) ge number($top/population)) 
      then $this else $top
    })
return $top/name

Saxon提供了一个扩展函数saxon：maximum，相当于例如：spec中最高的例子，所以你可以写

saxon:highest(//city, function($city){number($city/population)})/name

Answer 3

你可以试试这个：

//city[population = max(/countries/country/city/population)]/name

我怎么知道这个XML中人口最多的城市？

3 个答案: