Question

在定义BNF语法时，通常在定义它们之前使用它们，以便语法读作“前进”。

如何在coq中执行此操作并仍能逐步执行缓冲区？

Answer 1

在Coq中， buffer 的概念没有预先定义，因此很难理解你的意思。 Coq还有两个方面可以提供可能的前瞻感，并且可以在定义BNF语法时使用。

递归函数定义可以同时引入几个递归函数。
类型定义可以同时引入几种归纳类型。

在这两种情况下，定义的第一个对象可以在定义之前引用第二个对象。

以下是两个示例，第一个是递归函数。

Fixpoint even (n : nat) : bool :=
   match n with
     0 => true
   | S p => negb( odd p)
   end
with odd (n : nat) : bool :=
  match n with
    0 => false
  | S p => negb (even p)
  end.

在此示例中，您可以看到函数even在定义之前引用函数odd。

现在是第二个例子。我试着坚持你对BNF的主要比喻。语法描述可以作为归纳谓词给出。这是一个小例子，其中包含仅包含加法，乘法和自然数的算术表达式的语法。

Require Import String Ascii Arith.

Definition digit (c : ascii) : bool :=
  (nat_of_ascii "0" <=? nat_of_ascii c) &&
  (nat_of_ascii c <=? nat_of_ascii "9").

Fixpoint number (s : string) : bool :=
  match s with
  | String c EmptyString => digit c
  | String c tl => digit c && number tl
  | EmptyString => false
  end.

Inductive Exp1 : string -> Prop :=
  plus : forall x y, Exp2 x -> Exp1 y -> Exp1 (x ++ "+" ++ y)
| inj2 : forall x, Exp2 x -> Exp1 x
with
  Exp2 : string -> Prop :=
  times : forall x y, Exp3 x -> Exp2 y -> Exp2 (x ++ "*" ++ y)
| inj3 : forall x, Exp3 x -> Exp2 x
with
  Exp3 : string -> Prop :=
|  num : forall x, number x = true -> Exp3 x
|  inj1 : forall x, Exp1 x -> Exp3 ("(" ++ x ++ ")").

通过对语法的这种描述，我可以证明给定的表达式尊重语法。

Lemma example : Exp1 "3+2*(5*4)".
Proof.
apply (plus "3" "2*(5*4)").
  apply inj3.
  apply num; reflexivity.
apply inj2.
apply (times "2" "(5*4)").
  apply num; reflexivity.
apply inj3, (inj1 "5*4"), inj2, (times "5" "4").
  apply num; reflexivity.
apply inj3, num; reflexivity.
Qed.

这不描述解析器。这将是另一项练习。

您的问题非常简洁，我甚至不知道这是否是答案。

在为BNF样式定义定义之前使用标识符

1 个答案: