Question

我有以下代码，可以将光标位置检索为像素：

Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
' Create custom variable that holds two integers
Type POINTAPI
    Xcoord As Long
    Ycoord As Long
End Type

Sub GetCursorPosDemo()
    Dim llCoord As POINTAPI
    ' Get the cursor positions
    GetCursorPos llCoord
    ' Display the cursor position coordinates
    MsgBox "X Position: " & llCoord.Xcoord & vbNewLine & "Y Position: " & llCoord.Ycoord
End Sub

我希望它返回我的光标当前所在的单元格地址，或者可能是Points中的坐标，因此我可以将其转换为地址。这可能吗？

Answer 1

使用ActiveWindow.RangeFromPoint获取单元格地址。

Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
' Create custom variable that holds two integers
Type POINTAPI
    Xcoord As Long
    Ycoord As Long
End Type

Sub GetCursorPosDemo()
    Dim llCoord As POINTAPI
    Dim rng As Range
    ' Get the cursor positions
    GetCursorPos llCoord
    ' Display the cursor position coordinates
    'MsgBox "X Position: " & llCoord.Xcoord & vbNewLine & "Y Position: " & llCoord.Ycoord

    Set rng = GetRange(llCoord.Xcoord, llCoord.Ycoord)

    If Not rng Is Nothing Then
        MsgBox "Cell under mouse is :" & rng.Address
    Else
        MsgBox "Not a valid location."
    End If

End Sub

Function GetRange(x As Long, y As Long) As Range
    Set GetRange = ActiveWindow.RangeFromPoint(x, y)
End Function

VBA - 将光标位置作为单元格地址

1 个答案: