Question

我有一个任务是使用XSL模板和递归来计算斐波那契系列，但我不知道如何总结该系列。

我的代码现在。

<xsl:template name="fibonacci">
    <xsl:param name="n"/>
    <xsl:param name="sum" select="0"/>

    <xsl:choose>    
        <xsl:when test="$n = 0">
            <xsl:value-of select="$sum"/>
        </xsl:when>

        <xsl:when test="$n = 1">
            <xsl:value-of select="$sum + 1"/>
        </xsl:when>
            <xsl:otherwise>
                <xsl:call-template name="fibonacci">
                    <xsl:with-param name="n">
                        <xsl:value-of select="$n - 1"/>
                    </xsl:with-param>
                    <xsl:with-param name="final">
                        <xsl:value-of select="..."/>
                    </xsl:with-param>
                </xsl:call-template>
            </xsl:otherwise>
    </xsl:choose>
       </xsl:template>

Answer 1

模板应具有以下参数：

n1 - 系列中的第一个（上一个）号码（默认为0），
n2 - 系列中的第二个（下一个）数字（默认为1），
num - 要生成的元素数，从0开始。

它应该：

打印n1。
使用参数对自己进行强制调用：
- n1 = n2，
- n2 = n1 + n2，
- num减少一个（否则你会有一个无限循环）。

所以这个模板如下所示：

<xsl:template name="Fibon">
  <xsl:param name="n1" select="0"/>
  <xsl:param name="n2" select="1"/>
  <xsl:param name="num"/>

  <xsl:value-of select="$n1"/>

  <xsl:if test="$num &gt; 0">
    <xsl:text>, </xsl:text>
    <xsl:call-template name="Fibon">
      <xsl:with-param name="n1" select="$n2" />
      <xsl:with-param name="n2" select="$n1 + $n2" />
      <xsl:with-param name="num" select="$num - 1" />
    </xsl:call-template>
  </xsl:if>
</xsl:template>

要调用它，你必须只提供num参数，由于n1和n2具有默认值。

所以调用模板如下所示：

<xsl:template match="/">
  <result>
    <xsl:call-template name="Fibon">
      <xsl:with-param name="num" select="8" />
    </xsl:call-template>
  </result>
</xsl:template>

Answer 2

不是formula fib(n) = fib(n-1) + fib(n-2)种子fib(0) = 0和fib(1) = 1吗？

XSLT 1中的一个天真实现是

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

    <xsl:template name="fib">
        <xsl:param name="n"/>
        <xsl:choose>
            <xsl:when test="$n = 0">0</xsl:when>
            <xsl:when test="$n = 1">1</xsl:when>
            <xsl:otherwise>
                <xsl:variable name="n1">
                    <xsl:call-template name="fib">
                        <xsl:with-param name="n" select="$n - 1"/>
                    </xsl:call-template>
                </xsl:variable>
                <xsl:variable name="n2">
                    <xsl:call-template name="fib">
                        <xsl:with-param name="n" select="$n - 2"/>
                    </xsl:call-template>
                </xsl:variable>
                <xsl:value-of select="$n1 + $n2"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template match="/">
        <xsl:call-template name="fib">
            <xsl:with-param name="n" select="10"/>
        </xsl:call-template>
    </xsl:template>

</xsl:stylesheet>

给出输出

<root>
    <fib n="0">0</fib>
    <fib n="1">1</fib>
    <fib n="2">1</fib>
    <fib n="3">2</fib>
    <fib n="4">3</fib>
    <fib n="5">5</fib>
    <fib n="6">8</fib>
    <fib n="7">13</fib>
    <fib n="8">21</fib>
    <fib n="9">34</fib>
    <fib n="10">55</fib>
</root>

输入

<root>
    <item>0</item>
    <item>1</item>
    <item>2</item>
    <item>3</item>
    <item>4</item>
    <item>5</item>
    <item>6</item>
    <item>7</item>
    <item>8</item>
    <item>9</item>
    <item>10</item>
</root>

在http://xsltransform.hikmatu.com/3Nqn5Y4在线。

Answer 3

这对我有用：

<xsl:template name="fibonacci">
    <xsl:param name="n"/>
    <xsl:choose>    
        <xsl:when test="$n &lt;= 0">
            <xsl:value-of select="0"/>
        </xsl:when>
        <xsl:when test="$n = 1">
            <xsl:value-of select="1"/>
        </xsl:when>
        <xsl:when test="$n = 2">
            <xsl:value-of select="2"/>
        </xsl:when>
        <xsl:otherwise>
            <xsl:variable name="num1">
                <xsl:call-template name="fibonacci">
                    <xsl:with-param name="n">
                        <xsl:value-of select="$n - 1"/>
                    </xsl:with-param>
                </xsl:call-template>
            </xsl:variable>
            <xsl:variable name="num2">
                <xsl:call-template name="fibonacci">
                    <xsl:with-param name="n">
                        <xsl:value-of select="$n - 2"/>
                    </xsl:with-param>
                </xsl:call-template>
            </xsl:variable>
            <xsl:value-of select="$num1 + $num2"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

您可以使用以下方法测试代码：

<fo:block>
    <xsl:variable name="fib1">
        <xsl:call-template name="fibonacci">
            <xsl:with-param name="n" select="1"/>
        </xsl:call-template>
    </xsl:variable>
    <xsl:text>fib1: </xsl:text><xsl:value-of select="$fib1"/>

    <xsl:variable name="fib2">
        <xsl:call-template name="fibonacci">
            <xsl:with-param name="n" select="2"/>
        </xsl:call-template>
    </xsl:variable>
    <xsl:text>fib2: </xsl:text><xsl:value-of select="$fib2"/>

    <xsl:variable name="fib3">
        <xsl:call-template name="fibonacci">
            <xsl:with-param name="n" select="3"/>
        </xsl:call-template>
    </xsl:variable>
    <xsl:text>fib3: </xsl:text><xsl:value-of select="$fib3"/>

    <xsl:variable name="fib4">
        <xsl:call-template name="fibonacci">
            <xsl:with-param name="n" select="4"/>
        </xsl:call-template>
    </xsl:variable>
    <xsl:text>fib4: </xsl:text><xsl:value-of select="$fib4"/>

    <xsl:variable name="fib5">
        <xsl:call-template name="fibonacci">
            <xsl:with-param name="n" select="5"/>
        </xsl:call-template>
    </xsl:variable>
    <xsl:text>fib5: </xsl:text><xsl:value-of select="$fib5"/>
</fo:block>

XSL Fibonacci计算

3 个答案: