TADOStoredProc和SQL Server存储过程，参数为默认值

Question

我正在使用Delphi 7和SQL Server 2008.我创建了一个虚拟表和虚拟存储过程，如下所示。

CREATE TABLE [dbo].[Persons]
(
    [P_ID] [int] IDENTITY(1,1) NOT NULL,
    [LastName] [varchar](255) NOT NULL
)

CREATE PROCEDURE [dbo].[p_dummy_proc]
    @p_id int,
    @p_name VARCHAR(10) = 'dummy' -- donot pass anything from delphi and it should take 'dummy'
AS
BEGIN 
    IF (@p_name is null)
        RAISERROR 123456 'why are you null'
    ELSE  
        INSERT INTO dbo.persons(LastName) 
        VALUES(@p_name)
END

我在Delphi上调用上述程序，如下所示：

procedure TForm1.Button1Click(Sender: TObject);
begin
  try
    ADOStoredProc1.Parameters.ParamByName('@p_id').Value := 10;
    ADOStoredProc1.ExecProc; // error why are you null
  except
   on E: EDatabaseError do
     ShowMessage(e.Message);
  end;
end;

在Delphi代码中，我没有传递第二个参数，我期望SQL Server应该采用它的默认值。

当我执行存储过程时，我得到了错误。当我没有从Delphi传递任何东西时，为什么SQL Server没有采用默认值？

如果我将参数值设置为'dummy'，它将按预期工作。

Answer 1

TL; DR - 要使用默认的SP参数值集：

ADOStoredProc1.Parameters.ParamByName('@p_name').ParameterObject.Value := Unassigned

  

在Delphi代码中，我没有传递第二个参数而我是   期望SQL Server应该采用它的默认值。

是的，你是。您在设计时使用了一个已存在的参数，因此该参数显式地以NULL形式发送到SQL Server。您可以通过检查SQL事件探查器来验证这一点。

如果必须使用设计时参数，则无论何时要使用默认参数，都可以在运行时删除它，否则创建/分配它。例如（您可以为此制定一般方法）：

var
  Param: TParameter;
  ParamName: WideString;
  ParamValue: Variant;
  UseDefaultParameter: Boolean;
begin
  ParamName := '@p_name';
  Param := ADOStoredProc1.Parameters.FindParam(ParamName);
  UseDefaultParameter := True; // or False to assign a value

  if UseDefaultParameter then
  begin
    if Assigned(Param) then
      ADOStoredProc1.Parameters.Delete(Param.Index);
  end
  else
  begin
    ParamValue := 'boo!';
    if Assigned(Param) then
      Param.Value := ParamValue
    else
      ADOStoredProc1.Parameters.CreateParameter(ParamName, ftString, pdInput, 10, ParamValue);
  end;
end;

否则，请勿使用设计时参数并根据需要在运行时创建参数。更好的方法IMO是使用本地TADOStoredProc，在运行时创建它，分配参数，执行它并销毁它。

就个人而言，我在运行时创建TADOStoredProc并调用Parameters.Refresh()方法，该方法将从SQL Server查询（并创建）参数。然后我只是将值分配给我需要的参数。即使有一个额外的SQL Server之旅，在向SP添加新参数时也可以非常方便地进行维护 如果未设置参数值，ADO将启动exec命令，并使用default关键字设置参数。即

exec p_dummy_proc @p_id=1, @p_name=default

进一步挖掘后，我注意到问题实际上在TParameter.SetValue setter中。没有办法清除＆＃34;清除＆＃34;参数值：

procedure TParameter.SetValue(const Value: Variant);
begin
  if VarIsEmpty(Value) or VarIsNull(Value) then <--
    NewValue := Null
  else
  begin
    ...
  end;  
  ParameterObject.Value := NewValue;
end;

您可以看到，如果您将Value设置为NULL或Unassigned，ParameterObject.Value将设置为NULL（但绝不会设置为默认值）。

因此，如果您需要清除参数并使用默认值，则需要直接将TParameter.ParameterObject.Value设置为Unassigned：

if UseDefaultParameter then 
  SP.Parameters.ParamByName('@p_name').ParameterObject.Value := Unassigned
else
  SP.Parameters.ParamByName('@p_name').Value := 'boo!'