Question

定义理由反应绑定时，我想知道如何确定接受多种类型的绑定。例如，我有一个参数~value，它应该接受：string，number，array(string)或array(number)。目前我正在使用option('a)，但我不认为这是最干净的方法，因为我更愿意明确定义类型。如何才能做到这一点？我看过bs.unwrap，但我不确定如何将外部语法组合成函数签名。

module Select = {
  [@bs.module "material-ui/Select"] external reactClass : ReasonReact.reactClass = "default";
  let make =
      (
        ...
        ~menuProps: option(Js.t({..}))=?,
        ~value: option('a), /* Should be type to string, number, Array of string and Array of number */
        ~style: option(ReactDOMRe.style)=?,
        ...
        children
      ) =>
    ReasonReact.wrapJsForReason(
      ~reactClass,
      ~props=
        Js.Nullable.(
          {
            ...
            "value": from_opt(value),
            "style": from_opt(style)            
          }
        ),
      children
    );
};

作为一个附带问题，由于数字类型没有在原因中定义，我的绑定还必须将float和integer映射到数字中吗？

Answer 1

这可以通过使用以下内容（受https://github.com/astrada/reason-react-toolbox/启发）。

type jsUnsafe;

external toJsUnsafe : 'a => jsUnsafe = "%identity";

let unwrapValue =
    (r: [< | `Int(int) | `IntArray(array(int)) | `String(string) | `StringArray(array(string))]) =>
  switch r {
  | `String(s) => toJsUnsafe(s)
  | `Int(i) => toJsUnsafe(i)
  | `StringArray(a) => toJsUnsafe(a)
  | `IntArray(a) => toJsUnsafe(a)
  };

let optionMap = (fn, option) =>
  switch option {
  | Some(value) => Some(fn(value))
  | None => None
  };

module Select = {
  [@bs.module "material-ui/Select"] external reactClass : ReasonReact.reactClass = "default";
  let make =
      (
        ...
        ~menuProps: option(Js.t({..}))=?,
        ~value:
          option(
            [ | `Int(int) | `IntArray(array(int)) | `String(string) | `StringArray(array(string))]
           )=?,
        ~style: option(ReactDOMRe.style)=?,
        ...
        children
      ) =>
    ReasonReact.wrapJsForReason(
      ~reactClass,
      ~props=
        Js.Nullable.(
          {
            ...
            "value": from_opt(optionMap(unwrapValue, value)),
            "style": from_opt(style)            
          }
        ),
      children
    );
};

这可以通过以下方式使用;

<Select value=(`IntArray([|10, 20|])) />
<Select value=(`Int(10)) />

我从reason-react-toolbox复制了toJsUnsafe，所以我不完全确定它的作用，当我发现时，我会更新我的答案。

unwrapValue函数采用的值可以是列出的类型之一，并将其转换为jsUnsafe。

unwrapValue的类型允许列出的任何变体，但也允许其中的一部分，例如。（这是启用此功能的变体之前的<。）

let option = (value: option([ | `String(string) | `Int(int)])) =>
  Js.Nullable.from_opt(option_map(unwrapValue, value));

Answer 2

只是添加到@ InsidersByte的答案，因为这个问题不是特定于理由的反应，可以推广：

module Value = {
  type t;
  external int : int => t = "%identity";
  external intArray : array(int) => t = "%identity";
  external string : string => t = "%identity";
  external stringArray : array(string) => t = "%identity";
};

let values : list(Value.t) = [
  Value.int(4),
  Value.stringArray([|"foo", "bar"|])
];

此解决方案在Value模块中也是自包含的，并且与JavaScript等效项相比不会产生任何开销，因为"%identity"外部是无优化的优化。

如何使用reason-react定义在函数签名中接受多个类型的绑定？

2 个答案: