Question

我对Coq终止检查员的行为感到磕磕绊绊，我无法向自己解释。考虑：

Require Import Coq.Lists.List.

Record C a := {  P : a -> bool }.

Arguments P {_}.

Definition list_P {a} (a_C : C a) : list a -> bool := existsb (P a_C).

Definition list_C  {a} (a_C : C a) : C (list a) := {| P := list_P a_C |}.

(* Note that *)
Eval cbn in       fun a C => (P (list_C C)).
(* evaluates to:  fun a C  => list_P C *)

Inductive tree a := Node : a -> list (tree a) -> tree a.

(* Works, using a local record *)
Fixpoint tree_P1 {a} (a_C : C a) (t : tree a) : bool :=
    let tree_C := Build_C _ (tree_P1 a_C) in
    let list_C' := Build_C _ (list_P tree_C) in
    match t with Node _ x ts => orb (P a_C x) (P list_C' ts) end.

(* Works too, using list_P directly *)
Fixpoint tree_P2 {a} (a_C : C a) (t : tree a) : bool :=
    let tree_C := Build_C _ (tree_P2 a_C) in
    match t with Node _ x ts => orb (P a_C x) (list_P tree_C ts) end.

(* Does not work, using a globally defined record. Why not? *)
Fixpoint tree_P3 {a} (a_C : C a) (t : tree a) : bool :=
    let tree_C := Build_C _ (tree_P3 a_C) in
    match t with Node _ x ts => orb (P a_C x) (P (list_C tree_C) ts) end.

第一个和第二个例子表明，当试图了解一个修复点是否正在终止时，Coq能够解析记录访问者，基本上评估我们在tree_P1中写的内容，我们在tree_P2中写了什么

但这似乎只有在本地构建记录（let tree_C :=…）时才有效，而不是使用Definition定义记录。

但是Fixpoint可以很好地查看其他定义，例如通过list_P。那么记录有什么特别之处，我可以让Coq接受tree_P3吗？

Answer 1

在Coq中读完终止检查器之后，我想我找到了解决方案：

终止检查器将始终展示本地定义和beta-reduce。这就是tree_P1有效的原因。

如果需要，终止检查程序还会展开被调用的定义（例如list_C'，P，existsb），这就是tree_P2有效的原因。

但是，终止检查程序不会展开match … with条款中的适用定义，例如list_C。这是一个最小的例子：

(* works *)
Fixpoint foo1 (n : nat) : nat :=
  let t := Some True in 
  match Some True with | Some True => 0
                       | None => foo1 n end.

(* works *)
Fixpoint foo2 (n : nat) : nat :=
  let t := Some True in 
  match t with | Some True => 0
               | None => foo2 n end.

(* does not work *)
Definition t := Some True.

Fixpoint foo3 (n : nat) : nat :=
  match t with | Some True => 0
               | None => foo3 n end.

原始代码的解决方法是确保调用所有定义（而不是模式匹配），以确保终止检查器将展开它们。我们可以通过切换到延续传递方式来实现：

Require Import Coq.Lists.List.

Record C_dict a := {  P' : a -> bool }.

Definition C a : Type := forall r, (C_dict a -> r) -> r.

Definition P {a} (a_C : C a) : a -> bool :=
  a_C _ (P' _).

Definition list_P {a} (a_C : C a) : list a -> bool := existsb (P a_C).

Definition list_C  {a} (a_C : C a) : C (list a) :=
   fun _ k => k {| P' := list_P a_C |}.

Inductive tree a := Node : a -> list (tree a) -> tree a.

(* Works now! *)
Fixpoint tree_P1 {a} (a_C : C a) (t : tree a) : bool :=
    let tree_C := fun _ k => k (Build_C_dict _ (tree_P1 a_C)) in
    match t with Node _ x ts => orb (P a_C x) (P (list_C tree_C) ts) end.

这甚至适用于类型类，因为类型类解析不能解决这些问题：

Require Import Coq.Lists.List.

Record C_dict a := {  P' : a -> bool }.

Definition C a : Type := forall r, (C_dict a -> r) -> r.
Existing Class C.

Definition P {a} {a_C : C a} : a -> bool := a_C _ (P' _).

Definition list_P {a} `{C a} : list a -> bool := existsb P.

Instance list_C  {a} (a_C : C a) : C (list a) :=
   fun _ k => k {| P' := list_P |}.

Inductive tree a := Node : a -> list (tree a) -> tree a.

(* Works now! *)
Fixpoint tree_P1 {a} (a_C : C a) (t : tree a) : bool :=
    let tree_C : C (tree a) := fun _ k => k (Build_C_dict _ (tree_P1 a_C)) in
    match t with Node _ x ts => orb (P x) (P ts) end.

Answer 2

对于问题1.我相信在tree_P1中，类实例的定义在fix构造内部，并在终止检查时减少。

正如您正确指出的那样，以下定义被拒绝。

Fixpoint tree_P1' {a} `{C a} (t : tree a) : bool :=
    let tree_C := Build_C _ tree_P1' in
    match t with Node _ x ts => orb (P x) (@P _ (* mark *) _ ts) end.

在此定义中，注释(* mark *)之后所需的类实例由第7行的定义填充。但此定义位于fix构造之外且不会减少通过终止检查器以相同的方式。因此，未应用于任何树参数的tree_P1'的出现将保留在代码中，并且终止检查器将无法确定此出现仅用于小于最初的论点。

这是一个疯狂的猜测，因为我们无法看到被拒绝的函数的主体。

终止检查程序何时减少记录访问者

2 个答案: