Question

我在clojure中开发javafx-project，但我不能使用这些javafx的类：javafx.scene.layout.Hbox，javafx.scene.control.Label和javafx.scene.control。[没有Buttom的东西]。

我无法找到它的解决方案。

谢谢！

这是代码

温度/ core.clj

```

(ns temp.core
  (:import (javafx.application Application)
       (javafx.scene.text Text Font FontWeight)
       (javafx.scene.control Label TextField PasswordField Button)
       (javafx.scene.layout GridPane HBox)
       (javafx.scene.paint Color)
       (javafx.geometry Pos Insets)
       (javafx.event EventHandler)
       (javafx.stage Stage))
(:gen-class))

(def x (Label. "Hello"))
;; get message 
;; 2. Unhandled clojure.lang.Compiler$CompilerException
;; 1. Caused by java.lang.NoClassDefFoundError
;; javafx.scene.control.Labeled

(def H (HBox. 8))
;; get message
;; 1. Unhandled java.lang.IllegalArgumentException
;; No matching ctor found for class javafx.scene.layout.HBox

```

project.clj

(defproject temp "0.1.0-SNAPSHOT"
:description "FIXME: write description"
:url "http://example.com/FIXME"
:license {:name "Eclipse Public License"
          :url "http://www.eclipse.org/legal/epl-v10.html"}
:dependencies [[org.clojure/clojure "1.8.0"]]
:main temp.core
:aot [temp.core]
:target-path "target/%s"
:profiles {:uberjar {:aot :all}})

Answer 1

我可能会找到解决方案（我不知道为什么这个解决方案是正确的归因）

这是解决方案

(ns temp.core
 (:import (javafx.application Application)
   (javafx.scene.text Text Font FontWeight)
   (javafx.scene.control Label TextField PasswordField Button)
   (javafx.scene.layout GridPane HBox)
   (javafx.scene.paint Color)
   (javafx.geometry Pos Insets)
   (javafx.event EventHandler)
   (javafx.stage Stage))
(:gen-class))

(defn x [] (Label. "Hello"))

(defn H [] (HBox. 8))
;; return error in 'lein run' : 
;; java.lang.IllegalArgumentException: No matching ctor found for class 
;; javafx.scene.layout.HBox

请告诉我为什么这个解决方案正常工作

Answer 2

在初始化JavaFX运行时系统并启动它时，您还需要做更多的工作。这是一个非常小的项目。

这是Leiningen的项目文件。它与你所拥有的没有太大的不同。

(defproject fxdemo "0.1.0-SNAPSHOT"
  :description "FIXME: write description"
  :url "http://example.com/FIXME"
  :license {:name "Eclipse Public License"
            :url "http://www.eclipse.org/legal/epl-v10.html"}
  :dependencies [[org.clojure/clojure "1.8.0"]]
  :aot :all
  :main fxdemo.core)

一个非常小的程序，只显示JavaFX子系统的版本。

(ns fxdemo.core
  (:gen-class
    :extends javafx.application.Application)
  (:import (javafx.application Application)
           (javafx.scene.layout HBox)
           (javafx.scene.control Label)
           (javafx.scene Scene)
           (javafx.stage Stage)))

(defn -start
  "Build the application interface and start it all up. Called by the
  JavaFX runtime."
  [this stage]

  (let [ver (System/getProperty "javafx.runtime.version")
        lbl (Label. (str "JavaFX Version: " ver))
        root (HBox.)
        scene (Scene. root 250 150)]

    (.add (.getChildren root) lbl)

    (doto ^Stage stage
      (.setScene scene)
      (.setTitle "fxdemo")
      (.show))))

(defn -main
  "Start up the GUI part of the application."
  [& args]
  (Application/launch fxdemo.core args))

在我的系统上，执行lein run会显示此窗口：

您无法真正使用框架的各个部分，例如HBox和Label，而与框架无关。如果查看(gen-class...语句，则需要主程序扩展JavaFX Application类。要初始化JavaFX子系统，您需要使用Application/launch...方法，通常在程序入口函数中，如图所示。（有一些例外和其他方法可以做到这一点，但它们太复杂了，无法解释。这是最简单/最安全的方法。）当JavaFX子系统调用-start方法时，大部分已经初始化并准备好了。

另外，请注意在main和start函数名称之前的连字符“ - ”，这些是Java和Clojure之间的互操作的一部分。

如何使用Clojure的javafx.scene.layout.HBox和javafx.scene.control.Label

2 个答案: