Question

问题是，如何将CLOB数据从一个源数据库传输到另一个拥有DBLink的Oracle数据库。

Oracle无法使用DBLink传输CLOB数据，因此我们可以提供哪种解决方案：将Oracle中的字段扩展为Varchar2 32.767字符（Oracle 12的新功能）。

Answer 1

首先你需要临时表：

create global temporary table TBL_TMP_CLOB
(
  c_clob CLOB
)

第二次使用'从选择中插入'：

INSERT INTO schema.remote_table@dblink(rem_clob) SELECT * FROM TBL_TMP_CLOB;

Answer 2

我发布了一个Github项目，它通过dblink查询CLOB和BLOB。 https://github.com/HowdPrescott/Lob_Over_DBLink

这里有一个独立功能的CLOB部分：

create or replace function dblink_clob(
    p_dblink    in varchar2
  , p_clob_col  in varchar2
  , p_rid       in urowid
)
return clob is
    /**  A function to fetch a CLOB column over a dblink  **/
    /**  Laurence Prescott 25-Aug-17  **/
    /**  select dblink_clob('some_dblink', 'some_clob_column', rowid)
           from some_table@some_dblink;
         Note: Does not work on tables that have a virtual column (eg. xmltype).
    **/

    c_chunk_size    constant pls_integer := 4000;
    v_chunk         varchar2(4000);
    v_remote_table  varchar2(128);
    v_clob          clob;
    v_pos           pls_integer := 1;
begin
    dbms_lob.createtemporary(v_clob, true, dbms_lob.call);
    execute immediate 'select object_name from user_objects@' ||p_dblink
                   || ' where data_object_id = dbms_rowid.rowid_object(:bv_rid) '
    into v_remote_table using cast (p_rid as rowid);
    loop
        execute immediate 
            'select dbms_lob.substr@' ||p_dblink|| '(' ||p_clob_col|| ', ' ||c_chunk_size
         || ', ' ||v_pos|| ') from ' ||v_remote_table|| '@' ||p_dblink|| ' where rowid = :rid '
        into v_chunk using p_rid;
        begin dbms_lob.append(v_clob, v_chunk);
        exception when others then
            if sqlcode = -6502 then exit; else raise; end if;
        end;
        if length(v_chunk) < c_chunk_size then exit; end if;
        v_pos := v_pos + c_chunk_size;
    end loop;
    return v_clob;
end dblink_clob;

我认为这个例子是相当自我解释的，但这里有一点描述该函数依赖于以下事实：您可以跨dblink调用远程数据库上的函数/过程 - 在本例中为 dbms_lob.substr（）。
首先，它通过使用其对象ID（编码到 rowid 中）找到远程表名。这节省了必须将远程表名作为另一个参数传递另请注意，p_rid参数是 urowid ，因为它是来自远程数据库的 rowid 。这就是为什么需要施展的原因然后提取CLOB并以4000字节块重建，这是PL / SQL中的最大varchar2大小。这些块是varchar2，可以通过dblink传递 if length（v_chunk）＆lt;读完CLOB的最后一个后，满足c_chunk_size ... 子句（然后＆＃34; chunk＆＃34;缓冲区不会被填充）。
当CLOB的长度是4000的倍数时，需要 ORA-06502 的异常捕获，然后是＆＃34;如果＆＃34;即使没有更多数据，也不满足条款。你可以依靠这个捕获并删除＆＃34; if＆＃34;条款一共。但是我做了一些性能测试，发现在大多数情况下最好不要让它进入。

如何将CLOB数据从一个数据库传输到另一个具有DBLink的远程ORACLE数据库

2 个答案: