Question

TSQL MSSQL 2008r2

我需要帮助来修改数据。我到目前为止，现在需要帮助。

样本数据

[编辑]添加了附加示例

DECLARE @Table TABLE (NodePropertyValue NVARCHAR(50))
INSERT INTO @Table (NodePropertyValue)
VALUES 
    (N'AA11✏AAA ZZZZ'),
    (N'CRAP BB22✏BBB'),
    (N'CC55✏CC1'),
    (N'DD66✏666'),
    (N'EE55✏EEE     ES177'),
    (N'RUBBISH FF22✏FFF XXXXXX'),
    (N'NONSENSE')

我想像这样显示数据。如果存在NCHAR(9999)或铅笔且接下来的3个字符为字母，则在第三个字符后添加slash（/）。如果在添加slash后存在任何其他字符，则删除它们。因此，[AA11✏AAAZZZZ]应更新为[AA11✏AAA/]。

如果NCHAR(9999)存在且前4个字符前面有字符，则删除它们。因此，[CRAPBB22✏BBB]应更新至[BB22✏BBB/] [NONSENSE]应显示为NULL。

这是我所拥有的。如您所见，我坚持添加slash并删除不需要的字符。

SELECT
     V.NodePropertyValue 'Orignal'
    ,CASE   --Pencil NCHAR(9999) exists
        WHEN PATINDEX('%'+NCHAR(9999)+'%', UPPER(V.NodePropertyValue)) > 0
            THEN
                CASE 
                    WHEN --FIRST 4 chars match XX11 and 5th char equals NCHAR(9999) 
                        PATINDEX('[A-Z][A-Z][0-9][0-9]%', UPPER(V.NodePropertyValue)) > 0 
                        AND SUBSTRING(V.NodePropertyValue, PATINDEX('%[A-Z][A-Z][0-9][0-9]%', UPPER(V.NodePropertyValue))+ 4, 1) = NCHAR(9999)
                    THEN 
                        STUFF(V.NodePropertyValue, PATINDEX('[A-Z][A-Z][0-9][0-9]%', UPPER(V.NodePropertyValue))+ 4
                            , 50
                            , SUBSTRING(V.NodePropertyValue, PATINDEX('[A-Z][A-Z][0-9][0-9]%', UPPER(V.NodePropertyValue))+ 4, 50) )
                    WHEN --Any 4 chars match XX11 and preceding char is space and 5th char equals NCHAR(9999) 
                        PATINDEX('% [A-Z][A-Z][0-9][0-9]%', UPPER(V.NodePropertyValue)) > 0 
                        AND SUBSTRING(V.NodePropertyValue, PATINDEX('%[A-Z][A-Z][0-9][0-9]%', UPPER(V.NodePropertyValue))+ 4, 1) = NCHAR(9999)
                    THEN 
                        STUFF(V.NodePropertyValue, PATINDEX('% [A-Z][A-Z][0-9][0-9]%', UPPER(V.NodePropertyValue))+ 4
                            , 50
                            , SUBSTRING(V.NodePropertyValue, PATINDEX('% [A-Z][A-Z][0-9][0-9]%', UPPER(V.NodePropertyValue))+ 4, 50) )
                    ELSE
                        NULL
                END
        ELSE
            NULL
    END 'Updated'
FROM
    @Table V

Answer 1

如果铅笔后面总是有字母而没有数字，这是否足够？

select  case when patindex('%' + nchar(9999) + '%' , NodePropertyValue)=0 then null
            else substring( NodePropertyValue, patindex('%' + nchar(9999) + '%', NodePropertyValue)-4, 8) + '/'
        end as StringStart
from @Table

Answer 2

以下是获得所需结果的方法：

创建并填充样本表（我在评论中添加了一些基于我们对话的样本数据）

DECLARE @Table TABLE (NodePropertyValue NVARCHAR(50))
INSERT INTO @Table (NodePropertyValue)
VALUES 
(N'AA11✏AAA ZZZZ'),
(N'CRAP BB22✏BBB'),
(N'EE55✏EEE     ES177'),
(N'RUBBISH FF22✏FFF XXXXXX'),
(N'AA✏AAA ZZZZ'),
(N'AA✏A2A ZZZZ'),
(N'AA✏A'),
(N'NONSENSE')

计算所需模式的开始和结束的cte

;WITH CTE AS
(
SELECT NodePropertyValue,
       -- note: there are are 4 underscores before the pencil
       PATINDEX('%____'+ NCHAR(9999) +'[a-z][a-z][a-z]%', NodePropertyValue) As startPattern, 
       CHARINDEX(NCHAR(9999), NodePropertyValue) + 3 As EndPattern
FROM @Table
)

查询cte：

SELECT  NodePropertyValue, 
        CASE WHEN startPattern > 0 THEN
            SUBSTRING(NodePropertyValue, startPattern, EndPattern-startPattern+1) + '/'
        ELSE
            NULL
        END As Updated
FROM CTE

结果：

NodePropertyValue           Updated
AA11✏AAA ZZZZ               AA11✏AAA/
CRAP BB22✏BBB               BB22✏BBB/
EE55✏EEE     ES177          EE55✏EEE/
RUBBISH FF22✏FFF XXXXXX     FF22✏FFF/
AA✏AAA ZZZZ                 NULL
AA✏A2A ZZZZ                 NULL
AA✏A                        NULL
NONSENSE                     NULL

See a live demo on rextester.

TSQL使用SUBSTRING PATINDEX和STUFF来修改数据

2 个答案: