Question

我是MPI的新手，正在努力阅读二进制文件。具体来说，我有一个$ 198 \次50 \ times 50个整数数组（16位整数，具体而言）存储在二进制文件中。我想使用2个计算节点来处理这个文件。因此，有两个MPI进程，每个进程将处理一半的输入。我使用函数MPI_FILE_READ_AT来读取各个区域。我希望数组值填入我传入函数调用的变量/参数'bucket'。但是，从“桶”条目中打印出的健全性检查告诉我，桶中的值都是不正确的。我觉得我的论点出错了。

program main
use mpi
implicit none

integer :: i, error, num_processes, id, fh
integer(MPI_OFFSET_KIND) :: filesize, offset
integer(MPI_OFFSET_KIND) :: num_bytes_per_process
integer(MPI_OFFSET_KIND) :: num_bytes_this_process
integer ::   num_ints_per_process, num_ints_this_process
integer(kind = 2), dimension(:), allocatable  :: bucket
character(len=100) :: inputFileName
integer, parameter :: INTKIND=2

! Initialize
inputFileName =  'xyz_50x50'
print *, 'MPI_OFFSET_KIND =', MPI_OFFSET_KIND

! MPI basics
call MPI_Init ( error )
call MPI_Comm_size ( MPI_COMM_WORLD, num_processes, error )
call MPI_Comm_rank ( MPI_COMM_WORLD, id, error )

! Open the file
call MPI_FILE_OPEN(MPI_COMM_WORLD, inputFileName, MPI_MODE_RDONLY, &
           MPI_INFO_NULL, fh, error)

! get the size of the file
call MPI_File_get_size(fh, filesize, error)

! Note: filesize is the TOTAL number of bytes in the file
num_bytes_per_process = filesize/num_processes
num_ints_per_process = num_bytes_per_process/INTKIND 
offset = id * num_bytes_per_process

num_bytes_this_process = min(num_bytes_per_process, filesize - offset)
num_ints_this_process = num_bytes_this_process/INTKIND

allocate(bucket(num_ints_this_process))
call MPI_FILE_READ_AT(fh, offset, bucket, num_ints_this_process, &
              MPI_SHORT, MPI_STATUS_SIZE, error)

do i = 1, num_ints_this_process
    if (bucket(i) /= 0) then
       print *, "my id is ", id, " and bucket(",i,")=", bucket(i)
    endif
enddo

! close the file
call MPI_File_close(fh, error)

! close mpi 
call MPI_Finalize(error)

end program main

Answer 1

您必须使用MPI_STATUS_IGNORE代替MPI_STATUS_SIZE （fwiw，我无法编译这个程序，除非我解决这个问题）

call MPI_FILE_READ_AT(fh, offset, bucket, num_ints_this_process, &
              MPI_SHORT, MPI_STATUS_IGNORE, error)

请注意，由于所有MPI任务都在相同时读取文件，因此您更倾向于使用集合MPI_File_read_at_all()子例程来提高性能。

使用MPI I / O读取二进制文件时的结果不正确

1 个答案: