Question

我正在使用Automator来调整大量图像的大小。除了为PNG图像添加黑色背景的方式外，它的效果很好。如果图像是带有透明背景的黑色徽标，则这是一个真正的问题。有没有办法改变背景颜色？

我正在使用裁剪图像操作。

干杯！

Answer 1

Automator非常易于使用，但为了更有限的控制，您可以使用AppleScript（即使作为Automator的一部分）与Image Events进行一些基本的图像编辑包括使用具有特定尺寸和背景颜色的pad命令调整大小。这是一个基本脚本，您可以将其保存为Script Editor中的应用程序，然后使用它，双击Finder中的应用程序图标，或者更好地删除图像文件以处理应用程序图标：< / p>

property _width : 400
property _height : 200
property _color : {65528, 65535, 65525} --white

on run
    open (choose file with multiple selections allowed)
end run

on open the_items
    set output_folder to (((path to desktop) as string) & "Output")
    try
        get output_folder as alias
    on error
        tell application "Finder" to make new folder at desktop with properties {name:"Output"}
    end try
    repeat with this_item in the_items
        set this_item to (this_item as alias)
        set _info to info for this_item
        set _extension to _info's name extension
        if (_extension is in {"jpg", "jpeg", "tif", "tiff", "png"}) then
            set _name to name of _info
            set _name to (text 1 thru -((count _extension) + 1) of _name)
            set output_path to (output_folder & ":" & _name & "jpg")
            my resize_image(this_item, output_path, _width, _height)
        end if
    end repeat
end open

on resize_image(original_path, output_path, _width, _height)
    tell application "Image Events"
        launch
        set _image to (open file (original_path as string))
        pad _image to dimensions {_width, _height} with pad color _color -- use crop to dimensions to decrease the size
        save _image as JPEG in file output_path with icon
        close _image
    end tell
end resize_image

这将在桌面上创建一个名为Output的文件夹（如果尚不存在）并使用脚本顶部的尺寸将图像保存为JPG（您可以修改尺寸，颜色，输出位置等）。，这只是一个例子。）

批量调整OSX Automator白色背景中的图像大小而不是黑色

1 个答案: