Question

数组可以存储新值，这样做会返回一个新数组。我知道我可以使用MkApp函数来访问记录的选择器，我怎样才能替换记录的值？我正在使用.NET绑定，但作为问题的一个例子，这里有一些SMT：

(declare-datatypes (T1 T2) ((Pair (mk-pair (first T1) (second T2)))))
(declare-const p1 (Pair Int Int))
(declare-const p2 (Pair Int Int))
(assert (= p1 p2))
(assert (> (second p1) 20))
;How to replace (second p1) with 0
(check-sat)
(get-model)

Answer 1

我不认为有更新记录的 n 组件的统一方式，你基本上必须＆＃34;展开＆＃34;更新的定义：当更新数组 a 时，你基本上假设＆＃34; forall j，i是j和a [j]因此是新值，或者[ j]具有旧值＆＃34;。由于记录包含有限的多个元素，因此您可以展开相应的更新定义：

(declare-datatypes (T1 T2) ((Pair (mk-pair (first T1) (second T2)))))

(declare-const p1 (Pair Int Int))
(assert (= (first p1) 1))
(assert (= (second p1) 2)) ;; p1 is (1, 2)

(declare-const p2 (Pair Int Int))
(assert
  (and
    (= (first p2) (first p1))
    (= (second p2) 0)))

(check-sat)
(get-model) ;; p2 could be (1, 0)

这并不像具有内置更新功能那样简洁，但可以;特别是，如果您的SMT代码是由工具生成的。

您还可以引入更新关系（函数符号和量词也可以使用，但由于触发可能会出现问题）：

;; Read: "updating p1's second element to v yields p2"
(define-fun setSecond ((p1 (Pair Int Int)) (v Int) (p2 (Pair Int Int))) Bool ;; analogous for setFirst
  (and
    (= (first p2) (first p1))
    (= (second p2) v)))

(declare-const p3 (Pair Int Int))
(assert (setSecond p2 77 p3))

(check-sat)
(get-model) ;; p3 is (1, 77)

或者，更一般地说：

;; Read: "updating p1's ith element to v yields p2"
(define-fun setNth ((p1 (Pair Int Int)) (i Int) (v Int) (p2 (Pair Int Int))) Bool
  (and
    (= (first p2) (ite (= i 1) v (first p1)))
    (= (second p2) (ite (= i 2) v (second p1)))))

(declare-const p4 (Pair Int Int))
(assert (setNth p3 1 -77 p4))

(check-sat)
(get-model) ;; p4 is (-77, 77)

和以前一样，它可以直接从特定记录的定义中生成这些更新函数。

注意：尚未支持多态函数，您的每个元素类型setNth_T1_T2，T1都需要函数T2。

数据存储的等价数据用于记录

1 个答案: