Question

我已经找到了一种方法，可以使用Nat和Integer将Proxy转换为natVal，如下面的代码所示：

{-# LANGUAGE DataKinds #-}
{-# LANGUAGE ScopedTypeVariables #-}

module Main where

import Data.Proxy (Proxy)
import Data.Monoid ((<>))
import GHC.TypeLits

main :: IO ()
main = do
  fromNat (undefined :: Proxy 5)

fromNat :: KnownNat n => Proxy n -> IO ()
fromNat proxy = do
  let (num :: Integer) = natVal proxy -- converting a Nat to an Integer
  putStrLn $ "Some num: " <> show num

但是我无法想出一种将类型列表转换为常规列表的简单方法，下面的代码甚至不会进行类型检查：

{-# LANGUAGE DataKinds #-}
{-# LANGUAGE ScopedTypeVariables #-}

module Main where

import Data.Proxy (Proxy)
import Data.Monoid ((<>))
import GHC.TypeLits

main :: IO ()
main = do
  fromNat     (undefined :: Proxy 5)
  fromListNat (undefined :: Proxy '[2,3,10])

fromNat :: KnownNat n => Proxy n -> IO ()
fromNat proxy = do
  let (num :: Integer) = natVal proxy -- converting a Nat to an Integer
  putStrLn $ "Some num: " <> show num

fromListNat :: Proxy [Nat] -> IO ()
fromListNat = undefined

如何将类型列表转换为常规列表？

Answer 1

答案是制作类似KnownNat的内容，但适用于Nat的类型级别列表。我们使用类型类在类型级别列表上进行归纳。这个类型类通过其超类约束，将检查列表中的所有元素是否满足KnownNat，然后它将使用该事实来重构术语级列表。

{-# LANGUAGE TypeOperators, KindSignatures #-}

-- Similar to `KnownNat (n :: Nat)`
class KnownNatList (ns :: [Nat]) where
   natListVal :: proxy ns -> [Integer]

-- Base case
instance KnownNatList '[] where
  natListVal _ = []

-- Inductive step
instance (KnownNat n, KnownNatList ns) => KnownNatList (n ': ns) where
  natListVal _ = natVal (Proxy :: Proxy n) : natListVal (Proxy :: Proxy ns)

然后，fromListNat采用与fromNat相同的形状：

fromListNat :: KnownNatList ns => Proxy ns -> IO ()
fromListNat proxy = do
  let (listNum :: [Integer]) = natListVal proxy
  putStrLn $ "Some list of num: " <> show listNum

将这些更改拼接到您的初始代码中，我得到了预期的输出：

$ ghc Main.hs
$ ./Main
Some num: 5
Some list of num: [2,3,10]

从类型列表中获取常规列表

1 个答案: