Question

我正在研究一个宏，它将搜索整个工作簿中的各种代码。这些代码都是六位数字。我希望搜索的代码在名为＆＃34; Master＆＃34;的工作表的A列中输入。如果在另一个工作表上找到的代码与Master中的代码相匹配，则它的工作表名称和单元格将粘贴在它旁边的B列匹配中。成功时，最终结果如下所示。

下面发布的代码在某些情况下有效，但经常失败。有时会出现运行时错误，或出现错误消息＆＃34; 400＆＃34;没有别的。发生这些错误时，宏会在所有列出的代码末尾填充一个空白值匹配的行。这显然不是预期的功能。

我对上述错误感到茫然。我想知道限制搜索范围是否有助于稳定。其他工作表上的所有代码仅在A列中找到，因此在当前搜索所有列中的匹配非常浪费。速度是稳定性的次要因素，但我首先要消除所有失败点。

Sub MasterFill()

Dim rngCell As Range
Dim rngCellLoc As Range
Dim ws As Worksheet
Dim lngLstRow As Long
Dim lngLstCol As Long
Dim strSearch As String

Sheets("Master").Select
lngLstRowLoc = Sheets("Master").UsedRange.Rows.Count
Application.ScreenUpdating = False
    For Each rngCellLoc In Range("A1:A" & lngLstRowLoc)
    i = 1
        For Each ws In Worksheets
            If ws.Name = "Master" Then GoTo SkipMe
                lngLstRow = ws.UsedRange.Rows.Count
                lngLstCol = ws.UsedRange.Columns.Count
                ws.Select
                    For Each rngCell In Range(Cells(2, 1), Cells(lngLstRow, lngLstCol))
                        If InStr(rngCell.Value, rngCellLoc) > 0 Then
                            If rngCellLoc.Offset(0, i).Value = "" Then
                                rngCellLoc.Offset(0, i).Value = ws.Name & " " & rngCell.Address
                                i = i + 1
                            End If
                        End If
                    Next
SkipMe:
        Next ws
    Next
    Application.ScreenUpdating = True
    Worksheets("Master").Activate
    MsgBox "All done!"
End Sub

Answer 1

在纠正逻辑时，看看这是否不会加速。

Sub MasterFill()
    Dim addr As String, fndCell As Range
    Dim rngCellLoc As Range
    Dim ws As Worksheet

    Application.ScreenUpdating = False
    With Worksheets("Master")
        For Each rngCellLoc In .Range(.Cells(1, "A"), .Cells(.Rows.Count, "A").End(xlUp))
            For Each ws In Worksheets
                If LCase(ws.Name) <> "master" Then
                    With ws.Columns("A")
                        Set fndCell = .Find(what:=rngCellLoc.Value2, After:=.Cells(1), _
                                            LookIn:=xlFormulas, LookAt:=xlPart, _
                                            MatchCase:=False, SearchFormat:=False)
                        If Not fndCell Is Nothing Then
                            addr = fndCell.Address(0, 0)
                            Do
                                With rngCellLoc
                                    .Cells(1, .Parent.Columns.Count).End(xlToLeft).Offset(0, 1) = _
                                        Join(Array(ws.Name, fndCell.Address(0, 0)), Chr(32))
                                End With
                                Set fndCell = .FindNext(After:=fndCell)
                            Loop While addr <> fndCell.Address(0, 0)
                        End If
                    End With
                End If
            Next ws
        Next
        .Activate
    End With
    Application.ScreenUpdating = True
    MsgBox "All done!"
End Sub

我使用LookAt：= xlPart与你使用InStr的标准逻辑保持一致;如果您只对整个单元格值感兴趣，请将其更改为LookAt：= xlWhole。
我已将搜索范围限制在每个工作表中的A列。
在添加新结果之前，不会清除以前的结果。
您自己的错误是由Instr确定的任何其他字符串中找到零长度字符串（空白或vbNullString）的行为造成的。

VBA - 查找多个工作表的所有匹配项

1 个答案: