Question

我正在寻找一个通用程序，它将为Oracle数据库生成审计跟踪。我们目前在SQL Server上使用类似的过程，并想知道是否存在Oracle等效项。我们希望审计表将是一个单独的表而不是原始表，并包括用户/日期时间信息。

以下是我们使用的SQL Server等效项：https://www.codeproject.com/Articles/21068/Audit-Trail-Generator-for-Microsoft-SQL

非常感谢任何建议。

Answer 1

如果您不想使用Oracle本机机制，您可以拥有自己的框架来生成和读取您自己的审计表（我知道您可以，我曾经有类似的工作）。

以下是主要内容：

a_sqnc是您将在TrackTable中使用的序列，用于跟踪列NO_ORD中的操作顺序（即使还有一个D_UPD列，修改时间）。

create sequence a_sqnc
minvalue 1
maxvalue 99999999
start with 1
increment by 1
nocache;

TrackTable会有TABLE_NAME列，以便跟踪来自不同表格的更改。它还有PK_VALUE和ROW_VALUE，我们存储更改的数据。以下是使用有用索引创建的表：

create table TrackTable (
  table_name VARCHAR2(50) not null,
  action     VARCHAR2(240) not null,
  no_ord     NUMBER(12) not null,
  nature     VARCHAR2(3) not null,
  pk_value   VARCHAR2(4000),
  row_value  VARCHAR2(4000),
  ori        VARCHAR2(250),
  c_user     VARCHAR2(20),
  d_upd      DATE
);

create index AP_D_UPD on TrackTable (D_UPD);
create index AP_NO_ORD on TrackTable (NO_ORD);
create index AP_TABLE_NAME on TrackTable (TABLE_NAME);

假设您有一个简单的表BANK，其中包含两列PK_val（主键）和val：

create table BANK (
  pk_val VARCHAR2(50) not null,
  val    VARCHAR2(240) not null
);

alter table BANK
  add constraint BK_PK primary key (pk_val)
  using index ;

使用DBMS_APPLICATION_INFO.READ_MODULE(w_sess_mod, w_sess_act)了解哪个模块以及操作的操作：我在ORI中的TrackTable列中连接;
user Oracle会话变量可让您跟踪在c_user列中进行更改的人员;
以下是如何创建触发器TRCK_BNK来跟踪表BANK中的更改;它将分为3个操作：DELETE，UPDATE，INSERT（如果需要，您可以删除INSERT个案例。）

CREATE OR REPLACE TRIGGER "TRCK_BNK" 
AFTER DELETE OR INSERT OR UPDATE 
   ON BANK
REFERENCING NEW AS NEW OLD AS OLD
FOR EACH ROW

DECLARE
    w_a        VARCHAR2(10);
    W_ERRM     VARCHAR2(1000);
    W_CODE     VARCHAR2(1000);
    w_n        VARCHAR2(200) := 'BANK';
    w_id       NUMBER :=  a_sqnc.nextval;
    w_act      v$session.action%type;
    w_mod      v$session.module%type;
    w_ori      TrackTable.ORI%TYPE;    
BEGIN
  DBMS_APPLICATION_INFO.READ_MODULE(w_mod, w_act);
  w_ori := 'Module : '||w_mod ||' ; Action : '||w_act;
  ----------------------------------
  -- test which action is for change
  ----------------------------------
  IF UPDATING
  THEN
    w_a := 'UPDATE';
  ELSIF DELETING
  THEN
    w_a := 'DELETE';
  ELSIF INSERTING
  THEN
    w_a := 'INSERT';
  END IF;
  ----------------------------------
  -- Insert into TrackTable 
  ----------------------------------
If w_a in ('UPDATE', 'DELETE') then
  Insert into TrackTable 
       Select w_n, w_a, w_id, 'OLD', :OLD.pk_val, :OLD.val
            , w_ori, user, sysdate
         From Dual;
End if;

-- if you update, there is a new value and an old value
If w_a in ('UPDATE', 'INSERT') then
  Insert into TrackTable 
       Select w_n, w_a, w_id, 'NEW', :NEW.pk_val, :NEW.val
            , w_ori, user, sysdate
         From Dual;
End if;

Exception
When others then
  Begin
    W_ERRM := SQLERRM;
    W_CODE := SQLCODE;
    -- try inserting in case of error anyway
    Insert into TrackTable 
         Select w_n, w_a, -1, 'ERR', 'Grrr: '||W_CODE, W_ERRM
              , w_ori, user, sysdate
     From Dual;
  End;
End;
/

然后向框架添加函数，生成给定表的触发器，检索更改，将表还原到给定日期......

<强> NB：如果表格发生很大变化，这种跟踪表格上每个变化的方式都会损害表现。但对于几乎没有变化的参数表来说非常棒。

Answer 2

看看基于UNDO数据的Oracles Flashback Data Archive。它可以配置为跟踪对数据的任何更改。它自11g2（11.2.0.4）以来可用于任何版本的oracle。在Oracle documentation中，它表示最佳化是有限的，但任何版本都有基本功能。

Oracle - Audit Trail Generator？

2 个答案: