Question

我正在使用CLion和CMake进行项目构建。我创建了Google Test构建配置，我的项目树看起来像：

project tree

tokenizer的测试很简单：tokenizer应该打开源文件并输出令牌。

这是tokenizer_test的CMakeLists.txt文件：

include_directories(${gtest_SOURCE_DIRS}/include ${gtest_SOURCE_DIRS})
add_subdirectory(test_src)
add_executable(run_tokenizer_tests
    tokenizer_test.cpp ${CMAKE_SOURCE_DIR}/includes/tokenizer.h
    ${CMAKE_SOURCE_DIR}/src/tokenizer.cpp
)

target_link_libraries(run_tokenizer_tests gtest gtest_main)

我是否可以在附近的可执行文件中放置测试源（如图中的0.cpp），还是应该编写自己的测试脚本？我该怎么做？

Answer 1

您可以使用configure_file CMake功能，并带有COPYONLY标记。它将复制文件而不替换任何变量引用或其他内容。 CMakeLists.txt附近的tokenizer_test.cpp应包含：

configure_file(test_src/0.cpp 0.cpp COPYONLY)

PS：我建议你根据你正在进行的测试重命名每个源文件和输入文件，在你的情况下，0.cpp应该被命名为tokenizer_test_parse_input.cpp，最好放置这个文件靠近`tokenizer_test.cpp＆＃34;。

Answer 2

您可以致电file(COPY source DESTINATION ${CMAKE_CURRENT_BINARY_DIR})

有关其他变量，请参阅https://cmake.org/Wiki/CMake_Useful_Variables。

以下是我们项目中的代码段，可以执行此操作以及更多内容。

总的来说，如果您的构建目录处于活动状态，则此代码段允许您避免依赖于文件系统上的特定文件位置，因为文件路径将在您的单元测试中进行硬编码。

它简化了自动构建和检查 - 在调用测试运行器之前无需跟踪cd的位置。

它还提高了单元测试中代码的可读性。

CMakeLists.txt：

# list all test images

set(test_data

    orig_5_15Fps_3_27.png
    orig_5_15Fps_5_34.png
    ....
)

# Loop over all items in the "test_data" list
# Copy PNG, JPEG and BMP images to the directory, where test binaries are created
# And generate full paths to them for hardcoding in the include file test_config.h

foreach(df ${test_data})

    # copy images to build dir

    if(${df} MATCHES "((jp|pn)g|bmp)$")
        file(COPY ${df} DESTINATION ${CMAKE_CURRENT_BINARY_DIR})   
        set(df_file_path ${CMAKE_CURRENT_BINARY_DIR}/${df})
    else()
        set(df_file_path ${CMAKE_CURRENT_SOURCE_DIR}/${df}) 
    endif()

    # generate some C++ code in CMake variables IMAGE_PATHS and IMAGE_IDS
    # (see below)

    if (NOT IMAGE_PATHS)
        set(IMAGE_PATHS "    \"${df_file_path}\"")
    else()
        set(IMAGE_PATHS "${IMAGE_PATHS},\n    \"${df_file_path}\"")
    endif()

    string(REGEX REPLACE "[^a-zA-Z0-9]" "_" df_id ${df})

    if (NOT IMAGE_IDS)
        set(IMAGE_IDS "    img_${df_id}")
    else()
        set(IMAGE_IDS "${IMAGE_IDS},\n    img_${df_id}")
    endif()
endforeach()

set(TEST_PATH \"${CMAKE_CURRENT_BINARY_DIR}\")

configure_file(test_config.h.in test_config.h @ONLY)  # see below for test_config.h.in 

...
include_directories( ${CMAKE_CURRENT_BINARY_DIR} )   # make test_config.h visible for compiler
add_executable (some_unit_test some_unit_test.cpp)
add_test(NAME some_unit_test COMMAND some_unit_test WORKING_DIRECTORY ${EXECUTABLE_OUTPUT_PATH})
 ... 
add_executable ( ... )
add_test(  ... )
...

档案test_config.h.in。

/* DO NOT EDIT THIS FILE, IT IS AUTOGENERATED!
   All your changes will be overwritten.

   If you want to add new test data files, 
   add them to the `test_data` list in file CMakeLists.txt
*/ 

#ifndef __TEST_CONFIG_H__
#define __TEST_CONFIG_H__

const char* test_path = @TEST_PATH@; //!< full path to test data, without trailing slash

//! full paths to all test images
const char* image_paths[] = {
    @IMAGE_PATHS@
};

enum image_ids { //!< test file names, converted to enum constants
    @IMAGE_IDS@
};

#endif

致电configure_file取代@TEST_PATH@，@IMAGE_PATHS@和@IMAGE_IDS@及其值。

以下是构建目录中配置文件test_config.h的外观。

/* DO NOT EDIT THIS FILE, IT IS AUTOGENERATED!
   All your changes will be overwritten.

   If you want to add new test data files, 
   add them to the `test_data` list in file CMakeLists.txt
*/ 

#ifndef __TEST_CONFIG_H__
#define __TEST_CONFIG_H__

const char* test_path = "F:/projects/project/build64/test"; //!< full path to test data, without trailing slash


//! full paths to all test images
const char* image_paths[] = {
  "F:/projects/project/build64/test/orig_5_15Fps_3_27.png",
  "F:/projects/project/build64/test/orig_5_15Fps_5_34.png",
   ... 
};

enum image_ids { //!< test file names, converted to enum constants
    img_orig_5_15Fps_3_27_png,
    img_orig_5_15Fps_5_34_png,
...
};

#endif

在测试中使用：

#include "test_config.h"
....     
img0 = cv::imread(image_paths[img_orig_5_15Fps_3_27_png], cv::IMREAD_GRAYSCALE);

enum image_ids用于image_paths数组中的可读索引。恕我直言，它比image_paths[0]好得多，因为它清楚地显示了哪个图像被读取。

Cmake - 如何使用输入数据复制文件以构建输出文件夹

2 个答案: