Question

我是unix shell脚本的新手。我需要解析固定长度的数据文件并转换为逗号分隔符。我设法做到这一点。使用以下代码：

awk '{
 one=substr($0,1,1)
 two=substr($0,2,10)
 three=substr($0,12,4)
 four=substr($0,16,2)
 rest=substr($0,18)
 printf ("%s,%s,%s,%s,%s\n", one, two, three, four, rest)
}' data.txt > out.txt

DATA.TXT：

k12582927001611USNA
k12582990001497INAS
k12583053001161LNEU

Output.txt的：

k,1258292700,1611,US,NA
k,1258299000,1497,IN,AS
k,1258305300,1161,LN,EU

问题是我有要求阅读配置文件中的列位置。

我的configfile（configfile.txt）如下：

one=substr($0,1,1)
two=substr($0,2,10)
three=substr($0,12,4)
four=substr($0,16,2)
rest=substr($0,18)

为了满足要求，我创建了如下脚本：

configparam=`cat configfile.txt`
awk '{
$configparam
printf ("%s,%s,%s,%s,%s\n", one, two, three, four, rest)
}' data.txt > out.txt

但它不起作用。这里有人能告诉我实现这个目标的正确方法吗？

Answer 1

我已将其重组为

cat cfg.awk

{ 
   one=substr($0,1,1)
   two=substr($0,2,10)
   three=substr($0,12,4)
   four=substr($0,16,2)
   rest=substr($0,18)
}

cat printer.awk

{ printf ("%s,%s,%s,%s,%s\n", one, two, three, four, rest) }

以

运行

awk -f cfg.awk -f printer.awk data.txt

输出

k,1258292700,1611,US,NA
k,1258299000,1497,IN,AS
k,1258305300,1161,LN,EU

唯一的区别是您需要在{ .. }代码周围添加开始/结束var=substr（花括号）。

IHTH

Answer 2

最简单的方法是创建文件，其中包含位置开始和不包含下面的字符，您不必写这么多时间one=substr($0,start,n_char);：

输入：

$ cat infile 
k12582927001611USNA
k12582990001497INAS
k12583053001161LNEU

职位档案：

$ cat pos 
1,1
2,10
12,4
16,2
18

一衬垫：

$ awk 'BEGIN{FS=OFS=","}FNR==NR{pos[++i,"s"]=$1;pos[i,"e"]=$2+0?$2:length;next}{for(j=1; j<=i; j++) printf("%s%s", substr($0,pos[j,"s"],pos[j,"e"]),j==i?ORS:OFS)}' pos infile 
k,1258292700,1611,US,NA
k,1258299000,1497,IN,AS
k,1258305300,1161,LN,EU

更好的可读性：

awk 'BEGIN{
            FS=OFS=","
     }
     FNR==NR{
            pos[++i,"s"]=$1;
            pos[i,"e"]=$2+0?$2:length;
            next
     }
     {
          for(j=1; j<=i; j++) 
             printf("%s%s", substr($0,pos[j,"s"],pos[j,"e"]),j==i?ORS:OFS)
     }' pos infile

Answer 3

关注awk也可以帮助你。

awk '
function check(val, re){
  split(val, array,",");
  re=array[1] && array[2]?substr($0,array[1],array[2]):substr($0,array[1]);
  return re
}
FNR==NR{
  match($0,/\(.*\)/);
  a[FNR]=substr($0,RSTART+4,RLENGTH-5);
  count++;
  next}
{
for(i=1;i<=count;i++){
  val=val?val "," check(a[i]):check(a[i])
};
  print val;
  val=""
}
' Input_file_config   Input_file

输出如下。

k,1258292700,1611,US,NA
k,1258299000,1497,IN,AS
k,1258305300,1161,LN,EU

在AWK命令中从配置文件传递输入参数

3 个答案: