Question

我正在尝试测试模块化自由格式RPG方法，以便我们可以开始实际维护我们的代码，而不是游进去。当我决定尝试使用所有新的Dcl和Ctl语句来真正删除格式时，我在创建服务程序和模块以及分离我的代码方面做得非常好。

我只是尝试从“ILE RPG编程”一书中复制以下代码，但是当我调用它并传递参数时，程序中的值始终为0。就好像它没有看到输入参数。这是由于PTF和RDi版本控制，还是我错过了一些愚蠢的东西？为了记录，我在V7R1M0，RDi是版本9.5.1.0

   ctl-opt Main(Driver);

   dcl-pr Driver Extpgm('THISPGM');
       *n int(5);
   end-pr;

   Dcl-pr Celsius int(5);
     *n int(5);
   END-PR;

   dcl-proc Driver;
     Dcl-pi *n;
       Englishtemp int(5);
     END-PI;

   dcl-s Message char(50);
   dcl-S Metrictemp int(5);
   dcl-s State varchar(8);
   Metrictemp=Celsius(Englishtemp);
   Select;
     When Metrictemp<0;
       State='solid';
     When Metrictemp=0;
       State='Freezing';
     When Metrictemp=100;
       State='boiling';
     When Metrictemp>100;
       State='gaseous';
     other;
       State='liquid';
   ENDSL;

   Message='At '+%char(Englishtemp)+' degrees (' + %Char(Metrictemp)+
   ' Celsius), water is ' + State+'.';

       DSPLY Message;
       Return;
   END-PROC Driver;

   dcl-proc Celsius;
     dcl-pi *n int(5);
       Fahrenheit int(5);
     END-PI;
     dcl-s Temperature int(5);
     eval(h) Temperature = (5/9) * (Fahrenheit - 32 );
     Return Temperature;
   END-PROC Celsius;

Answer 1

程序代码没问题。我认为你搞砸了从命令行传递参数。您将所有内容定义为int（5），这是一个2字节的整数。

将参数传递给RPG程序的最安全的方法（特别是非类型字符的）是使用命令。

CMD  PROMPT('Temperature')

PARM KWD(TEMP) TYPE(*INT2) PROMPT('Temperature in °F')

注意：令人遗憾的是，IBM并没有在整个语言中保持一致。 * CMD中的INT2 = RPG中的INT（5）

将参数传递给自由格式RPG Linear-Main程序的问题

1 个答案: