Question

nRaizes :: Floating a => a -> a -> a -> a
  nRaizes a b c = let r = b^2 - 4 * a * c
                  in if r < 0
                     then 0
                     else if r == 0
                     then 1
                     else 2

所以我得到了这个代码，我正在检查方程的根数。但是当我尝试编译它时，它给了我这个。

 Could not deduce (Ord a) arising from a use of ‘<’
    from the context (Floating a)
      bound by the type signature for
                 nRaizes :: Floating a => a -> a -> a -> a
      at Ficha1.hs:29:14-43
    Possible fix:
      add (Ord a) to the context of
        the type signature for nRaizes :: Floating a => a -> a -> a -> a
    In the expression: r < 0
    In the expression: if r < 0 then 0 else if r == 0 then 1 else 2
    In the expression:
      let r = b ^ 2 - 4 * a * c
      in if r < 0 then 0 else if r == 0 then 1 else 2

Ficha1.hs:33:32:
    Could not deduce (Eq a) arising from a use of ‘==’
    from the context (Floating a)
      bound by the type signature for
                 nRaizes :: Floating a => a -> a -> a -> a
      at Ficha1.hs:29:14-43
    Possible fix:
      add (Eq a) to the context of
        the type signature for nRaizes :: Floating a => a -> a -> a -> a
    In the expression: r == 0
    In the expression: if r == 0 then 1 else 2
    In the expression: if r < 0 then 0 else if r == 0 then 1 else 2

是的，我是个打手。我甚至不能理解什么是错的。这是一个浮动数字，为什么不能比较呢？我只知道它与签名有关，因为如果我删除它就可以了

Answer 1

这是一个浮动数字，为什么不能比较呢？

不，它本身不是的浮点数。严格来说，Floating意味着您可以在其上执行三角和双曲函数。这是否意味着它是一个浮点数，是一个不同的方面（虽然它有点相关）。

话虽如此，但暗示您可以比较两个元素。但这不是问题：我们可以将类型类Ord a添加到它：

nRaizes :: (Floating a, Ord a) => a -> a -> a -> a
nRaizes a b c = let r = b^2 - 4 * a * c
                  in if r < 0
                     then 0
                     else
                         if r == 0
                         then 1
                         else 2

但是我们定义了我们的功能太严格了。为什么我们需要三角函数和双曲函数？为什么不用Ord定义*所有可能数字表示的函数？因此，我们可以将函数概括为：

nRaizes :: (Num a, Ord a) => a -> a -> a -> a
nRaizes a b c = let r = b^2 - 4 * a * c
                  in if r < 0
                     then 0
                     else
                         if r == 0
                         then 1
                         else 2

此外，虽然大多数人喜欢圣诞节。大多数程序员不喜欢圣诞树作为函数定义。也许更优雅的方法是使用警卫代替if - then - else s：

nRaizes :: (Num a, Ord a) => a -> a -> a -> a
nRaizes a b c | r < 0 = 0
              | r == 0 = 1
              | otherwise = 2
    where r = b*b - 4*a*c

最后，我们会产生三种可能的输出：0，1和2。但没有任何内容表明输出类型应与a，b和c的类型相同。所以我们可以将输入和输出的类型分成：

nRaizes :: (Num a, Ord a, Num b) => a -> a -> a -> b
nRaizes a b c | r < 0 = 0
              | r == 0 = 1
              | otherwise = 2
    where r = b*b - 4*a*c

编译错误 - 无法推断出Ord

1 个答案: