将两个xsl文件的功能合并到一个文件中（不是xsl导入或包含问题）

时间：2011-01-10 07:34:25

标签： xslt

我有两个xsl文件;他们俩一个接一个地在源xml上执行不同的任务。现在我需要一个单独的xsl文件，它将在单个文件中实际执行这两个任务（它不是xsl import或xsl include的问题）：

说我的源xml是：

<LIST_R7P1_1>
    <R7P1_1>
        <LVL2>
            <ORIG_EXP_PRE_CONV>#+#</ORIG_EXP_PRE_CONV>
            <EXP_AFT_CONV>abc</EXP_AFT_CONV>
            <GUARANTEE_AMOUNT>#+#</GUARANTEE_AMOUNT>
            <CREDIT_DER/>
        </LVL2>
        <LVL21>
            <AZ>#+#</AZ>
            <BZ>bz1</BZ>
            <AZ>az2</AZ>
            <BZ>#+#</BZ>
            <CZ/>
        </LVL21>
    </R7P1_1>
</LIST_R7P1_1>

我的第一个xsl（tr1.xsl）删除所有值为空或空的节点： 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="@*|node()">
        <xsl:if test=". != '' or ./@* != ''">
            <xsl:copy>
                <xsl:apply-templates select="@*|node()"/>
            </xsl:copy>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

此处的输出是

<LIST_R7P1_1>
    <R7P1_1>
        <LVL2>
            <ORIG_EXP_PRE_CONV>#+#</ORIG_EXP_PRE_CONV>
            <EXP_AFT_CONV>abc</EXP_AFT_CONV>
            <GUARANTEE_AMOUNT>#+#</GUARANTEE_AMOUNT>
        </LVL2>
        <LVL21>
            <AZ>#+#</AZ>
            <BZ>bz1</BZ>
            <AZ>az2</AZ>
            <BZ>#+#</BZ>
        </LVL21>
    </R7P1_1>
</LIST_R7P1_1>

我的第二个xsl（tr2.xsl）在第一个xsl的输出上执行全局替换（＃+＃，文本为空白''）： 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
     version="1.0">
    <xsl:template name="globalReplace">
        <xsl:param name="outputString"/>
        <xsl:param name="target"/>
        <xsl:param name="replacement"/>
        <xsl:choose>
            <xsl:when test="contains($outputString,$target)">
                <xsl:value-of select=
        "concat(substring-before($outputString,$target),
               $replacement)"/>
                <xsl:call-template name="globalReplace">
                    <xsl:with-param name="outputString"
             select="substring-after($outputString,$target)"/>
                    <xsl:with-param name="target" select="$target"/>
                    <xsl:with-param name="replacement"
             select="$replacement"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$outputString"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    <xsl:template match="text()">
        <xsl:call-template name="globalReplace">
            <xsl:with-param name="outputString" select="."/>
            <xsl:with-param name="target" select="'#+#'"/>
            <xsl:with-param name="replacement" select="''"/>
        </xsl:call-template>
    </xsl:template>
    <xsl:template match="@*|*">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

所以最终输出是 

<LIST_R7P1_1>
    <R7P1_1>
        <LVL2>
            <ORIG_EXP_PRE_CONV></ORIG_EXP_PRE_CONV>
            <EXP_AFT_CONV>abc</EXP_AFT_CONV>
            <GUARANTEE_AMOUNT></GUARANTEE_AMOUNT>
        </LVL2>
        <LVL21>
            <AZ></AZ>
            <BZ>bz1</BZ>
            <AZ>az2</AZ>
            <BZ></BZ>
        </LVL21>
    </R7P1_1>
</LIST_R7P1_1>

我担心的是，除了这两个xsl（tr1.xsl和tr2.xsl）之外，我只需要一个xsl（tr.xsl）来给我最终输出吗？

说我将这两者合并为 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="@*|node()">
        <xsl:if test=". != '' or ./@* != ''">
            <xsl:copy>
                <xsl:apply-templates select="@*|node()"/>
            </xsl:copy>
        </xsl:if>
    </xsl:template>
    <xsl:template name="globalReplace">
        <xsl:param name="outputString"/>
        <xsl:param name="target"/>
        <xsl:param name="replacement"/>
        <xsl:choose>
            <xsl:when test="contains($outputString,$target)">
                <xsl:value-of select=
        "concat(substring-before($outputString,$target),
               $replacement)"/>
                <xsl:call-template name="globalReplace">
                    <xsl:with-param name="outputString"
             select="substring-after($outputString,$target)"/>
                    <xsl:with-param name="target" select="$target"/>
                    <xsl:with-param name="replacement"
             select="$replacement"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$outputString"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    <xsl:template match="text()">
        <xsl:call-template name="globalReplace">
            <xsl:with-param name="outputString" select="."/>
            <xsl:with-param name="target" select="'#+#'"/>
            <xsl:with-param name="replacement" select="''"/>
        </xsl:call-template>
    </xsl:template>
    <xsl:template match="@*|*">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

输出： 

<LIST_R7P1_1>
    <R7P1_1>
        <LVL2>
            <ORIG_EXP_PRE_CONV></ORIG_EXP_PRE_CONV>
            <EXP_AFT_CONV>abc</EXP_AFT_CONV>
            <GUARANTEE_AMOUNT></GUARANTEE_AMOUNT>
            <CREDIT_DER/>
        </LVL2>
        <LVL21>
            <AZ></AZ>
            <BZ>bz1</BZ>
            <AZ>az2</AZ>
            <BZ></BZ>
            <CZ/>
        </LVL21>
    </R7P1_1>
</LIST_R7P1_1>

仅执行替换但不删除空/空节点。

2 个答案:

答案 0 :(得分：4)

该问题的一般解决方案是在一个样式表中更改模板规则和apply-templates调用以使用模式M1，在另一个样式中更改模板M2，然后将它们组合使用，如下所示：

<xsl:template match="/">
  <xsl:variable name="temp">
    <xsl:apply-templates select="." mode="M1"/>
  </xsl:variable>
  <xsl:apply-templates select="$temp" mode="M2"/>
</xsl:template>

但是在XSLT 1.0中，第二个apply-templates需要

<xsl:apply-templates select="exslt:node-set($temp)" mode="M2"/>

答案 1 :(得分：2)

这个XSLT：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="@* | node()">
    <xsl:copy>
        <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="text()">
    <xsl:call-template name="globalReplace">
        <xsl:with-param name="outputString" select="."/>
        <xsl:with-param name="target" select="'#+#'"/>
        <xsl:with-param name="replacement" select="''"/>
    </xsl:call-template>
</xsl:template>    

<xsl:template match="*[not(text()) and not(*) and not(@*)]"/>

<xsl:template name="globalReplace">
    <xsl:param name="outputString"/>
    <xsl:param name="target"/>
    <xsl:param name="replacement"/>
    <xsl:choose>
        <xsl:when test="contains($outputString,$target)">
            <xsl:value-of
                    select="concat(
                    substring-before($outputString,$target)
                    ,$replacement)"/>
            <xsl:call-template name="globalReplace">
                <xsl:with-param name="outputString"
                                select="substring-after($outputString,$target)"/>
                <xsl:with-param name="target" select="$target"/>
                <xsl:with-param name="replacement" select="$replacement"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$outputString"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

应用于这个格式良好的XML：

<?xml version="1.0" encoding="UTF-8"?>
<LIST_R7P1_1>
  <R7P1_1>
    <LVL2>
        <ORIG_EXP_PRE_CONV>#+#</ORIG_EXP_PRE_CONV>
        <EXP_AFT_CONV>abc</EXP_AFT_CONV>
        <GUARANTEE_AMOUNT>#+#</GUARANTEE_AMOUNT>
        <CREDIT_DER/>
    </LVL2>
    <LVL21>
        <AZ>#+#</AZ>
        <BZ>bz1</BZ>
        <AZ>az2</AZ>
        <BZ>#+#</BZ>
        <CZ/>
        <ONE_MORE_TEST>#+#OLOLO</ONE_MORE_TEST>
    </LVL21>
  </R7P1_1>
</LIST_R7P1_1>

产生这个结果：

<?xml version="1.0" encoding="UTF-8"?>
<LIST_R7P1_1>
  <R7P1_1>
    <LVL2>
        <ORIG_EXP_PRE_CONV/>
        <EXP_AFT_CONV>abc</EXP_AFT_CONV>
        <GUARANTEE_AMOUNT/>
    </LVL2>
    <LVL21>
        <AZ/>
        <BZ>bz1</BZ>
        <AZ>az2</AZ>
        <BZ/>
        <ONE_MORE_TEST>OLOLO</ONE_MORE_TEST>
    </LVL21>
  </R7P1_1>
</LIST_R7P1_1>
相关问题
最新问题