Question

我的问题是我如何提取所有属性以及在wikidata网页上呈现的各个标签，最好是通过SPARQL。

以wikidata上的Google条目为例。对于物业P414（证券交易所）或P159，有像P969（位于街道地址）的子属性。它们实际上会以query wbgetentities作为限定条件出现。 wbgetentities的问题在于缺少标签。我使用以下SPARQL查询获得所需的输出（例如wdt:P17 => country => United States of America）：

SELECT ?prop_id ?prop_label ?prop_val_label WHERE {
  VALUES (?company) {
    (wd:Q95)
  }
  ?company ?prop_id ?company_item.
  ?wd wikibase:directClaim ?prop_id.
  ?wd rdfs:label ?prop_label.
  OPTIONAL {
    ?company_item rdfs:label ?prop_val.
    FILTER((LANG(?prop_val)) = "en")
  }
  BIND(COALESCE(?prop_val, ?companyItem) AS ?prop_val_label)
  FILTER((LANG(?prop_label)) = "en")
}

但那些＆＃34;子属性＆＃34;因为没有直接索赔而失踪。要提取单个语句限定符，我可以这样做：

SELECT ?company ?hq ?country WHERE {
  wd:Q95 p:P159 ?company.
  OPTIONAL {
    ?company ps:P159 ?hq.
    ?company pq:P17 ?country. 
  }
}

但问题是，是否有办法将所有内容组合到一个查询中？

Answer 1

维基数据模型上的有用链接：

您的查询应该属于这种类型：

SELECT ?wdLabel ?ps_Label ?wdpqLabel ?pq_Label {
  VALUES (?company) {(wd:Q95)}

  ?company ?p ?statement .
  ?statement ?ps ?ps_ .

  ?wd wikibase:claim ?p.
  ?wd wikibase:statementProperty ?ps.

  OPTIONAL {
  ?statement ?pq ?pq_ .
  ?wdpq wikibase:qualifier ?pq .
  }

  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
} ORDER BY ?wd ?statement ?ps_

Try it!

结果中仅包含限定符及其值。既不包括起源参考也不包括值注释（例如时间精度）。如果您需要添加评论，请写评论。

wikidata获取包含项目标签和值的所有属性

1 个答案: