Question

我在machine1上创建了一个Mnesia数据库/ Schema。该节点名为mypl @ machine1。然后我将所有文件移动到machine2，因为machine1崩溃了。只要代码运行时名称为“mypl @ machine1”，一切运行正常。显然这有点令人担忧，因为它现在在机器2上运行。

如果我使用节点名称“mypl @ machine2”启动Erlang，则Mnesia数据库显示为空。

如何将Mnesia数据库中的节点从machine1重命名为machine2？

Answer 1

我不认为这可以在一个节点上在线完成（任何人？），但除了运行两个节点和添加表副本之外，还可以通过备份/恢复来完成。在Mnesia User's guide部分6.9.1中，您将找到一些使用mnesia：traverse_backup的代码来更改mnesia备份文件中架构表（如下所示）中的节点名称。您应该使用的模块名称是mnesia_backup。

使用此代码，您需要：

%% On mypl@machine1
mnesia:backup("/path/to/mnesia.backup").
change_node_name(mnesia_backup, mypl@machine1, mypl@machine2,
                 "/path/to/mnesia.backup", "/path/to/new.mnesia.backup").
%% On mypl@machine2
mnesia:restore("/path/to/new.mnesia.backup", []).

我不确定您是否需要先在mypl@machine2上创建架构。

用户指南中的更改节点名称代码：

change_node_name(Mod, From, To, Source, Target) ->
    Switch =
        fun(Node) when Node == From -> To;
           (Node) when Node == To -> throw({error, already_exists});
           (Node) -> Node
        end,
    Convert =
        fun({schema, db_nodes, Nodes}, Acc) ->
                {[{schema, db_nodes, lists:map(Switch,Nodes)}], Acc};
           ({schema, version, Version}, Acc) ->
                {[{schema, version, Version}], Acc};
           ({schema, cookie, Cookie}, Acc) ->
                {[{schema, cookie, Cookie}], Acc};
           ({schema, Tab, CreateList}, Acc) ->
                Keys = [ram_copies, disc_copies, disc_only_copies],
                OptSwitch =
                    fun({Key, Val}) ->
                            case lists:member(Key, Keys) of
                                true -> {Key, lists:map(Switch, Val)};
                                false-> {Key, Val}
                            end
                    end,
                {[{schema, Tab, lists:map(OptSwitch, CreateList)}], Acc};
           (Other, Acc) ->
                {[Other], Acc}
        end,
    mnesia:traverse_backup(Source, Mod, Target, Mod, Convert, switched).

Answer 2

解决方法是迁移。只需启动mnesia集群并将所有表和架构迁移到其他节点。比从原版中删除并忘记了。

如何重命名运行mnesia数据库的节点

2 个答案: