阴影沿y轴有界区域

Question

我绘制了一条线但是想要沿y轴遮蔽2到4之间的区域来说明曲线下方的区域，但无法弄清楚如何做到这一点，任何人都可以帮忙吗？这是代码，这很简单

>y:=(2*x);

>plot(y,x=0..3);

Answer 1

我发现很难理解你所在的地区。

这是吗？

restart;

y := 2*x:

plots:-display(
  plot(2*x, x=0..3),
  plots:-inequal([Y>=y, Y>=2, Y<=4], x=0..3, Y=0..6,
                 'nolines', 'color'="Burgundy")
);

当然，您可以省略删除上面y=2*x by调用的曲线（行）plot。

如果您还有其他一些地区，那么您应该可以相应地调整plots:-inequal的来电。

还有其他方法可以完成此类操作，例如使用plot选项调用filled。您还可以使用plottools:-reflect或使用plot的参数调用序列来翻转x和y轴。

我认为您可能希望避免为＆＃34;解决x＆＃34;，以获得与x和y=2相对应的y=4值（即使在这个y=2*x的例子你可以在脑海中做到这一点。

这就是为什么我认为您最容易使用plots:-inequal的原因。

[编辑：关于8个矩形的后续评论]

首先，一个稍微不同的例子，希望更清晰。

restart;

x:=arcsin(y/6):

P := plots:-display(
  plot(x, y=2..5),
  plots:-inequal([X<=x], y=2..5, X=0..1.2,
                 'nolines', 'color'=pink)
):

plots:-display(
  plot(2, color=black, linestyle=dot),
  plot(5, color=black, linestyle=dot),
  plot([x, y, y=0..6]),
  plottools:-transform((x,y)->[y,x])(P),
  view=[0..1.2,0..6],
  labels=["x","y"],
  size=[500,300]
);

可以使用RiemannSum包中的Student:-Calculus1命令显示较低总和的上限（使用矩形）。 （或者你可以使用seq命令并通过公式为他们的角落构建它们 - 但这看起来像是很多笨拙的簿记。）

您当然可以删除下面传递给plots:-display命令的任何部分。

restart;

with(Student:-Calculus1):

x:=arcsin(y/6):

P:=RiemannSum(x, y=2..5, method = upper, output = plot,
              partition=8,
              boxoptions=[filled=[color=pink,transparency=.5]],
              caption=""):

rP:=plottools:-transform((x,y)->[y,x])(P):

plots:-display(
  plot(2, color=black, linestyle=dot),
  plot(5, color=black, linestyle=dot),
  plot([x, y, y=0..6]),
  rP,
  view=[0..1.2,0..6],
  labels=["x","y"],
  size=[500,300]
);

或者，

restart;

with(Student:-Calculus1):

x:=arcsin(y/6):

P:=RiemannSum(x, y=2..5, method = lower, output = plot,
              partition=8,
              boxoptions=[filled=[color=pink,transparency=.5]],
              caption=""):

rP:=plottools:-transform((x,y)->[y,x])(P):

plots:-display(
  plot(2, color=black, linestyle=dot),
  plot(5, color=black, linestyle=dot),
  plot([x, y, y=0..6]),
  rP,
  view=[0..1.2,0..6],
  labels=["x","y"],
  size=[500,300]
);

如果你想要曲线和x轴之间的区域，那么所有这些例子都会有点复杂。