SPSS-如何使直方图模板将y轴称为百分比

Question

关于SPSS（版本20）使用图表模板，我有一个奇怪的问题，任何帮助都会受到关注。

我使用GUI来手动定义直方图的图表模板。这些是简单的定义：

1）将x轴设置在0到100之间。

2）将y轴设置为百分比，而不是每个箱内的实际实例数。

3）将箱子大小设置为5。

4）将y轴的最大值设置为20。

在更改了一个直方图的定义后，我使用File-＆gt; Save ChartTemplate选项保存了模板。

奇怪的是，当我在新的直方图上实现模板时，只生成了定义1,3,4，而省略了2。我搜索了一个解决方案，没有找到任何解决方案。这是非常令人沮丧的，因为我需要浪费时间和精力，在我制作的任何新直方图上手动将轴重置为正确的定义（这很多：/）。

可能有一种方法可以使用记事本来破解模板代码，但我没有看到任何提到Y轴的信息。

任何帮助和评论都会受到很多关注。

Answer 1

我不能随便说明如何设置模板来执行这些方面，但这里有一个使用语法来指定这四个选项的示例。

SET SEED 10.
INPUT PROGRAM.
LOOP #i = 1 TO 500.
  COMPUTE Var = RV.UNIFORM(0,90).
  END CASE.
END LOOP.
END FILE.
END INPUT PROGRAM.
DATASET NAME Sim.
FORMATS Var (F3.0).
EXECUTE.


GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=Var MISSING=LISTWISE REPORTMISSING=NO
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
  SOURCE: s=userSource(id("graphdataset"))
  DATA: Var=col(source(s), name("Var"))
  GUIDE: axis(dim(1), label("Var"), delta(5))
  GUIDE: axis(dim(2), label("Percent in Bin"))
  SCALE: linear(dim(1), min(0), max(100))
  SCALE: linear(dim(2), max(20))
  ELEMENT: interval(position(summary.percent.count(bin.rect(Var, binWidth(5)), base.all(acrossPanels()))))
END GPL.

这就是图表在V25中对我（使用我的默认图表模板）的样子。