Question

我有关于医院病人的RDF数据，包括他们的出生日期。经常多个三元组与其出生日期相邻，而其中一些三元组可能是错误的。我的小组已决定使用此规则：最常出现的日期将暂时被视为正确。它清楚如何在我们选择的任何编程语言中执行此操作，在SPARQL外部。

是否可以在SPARQL中聚合聚合？

我已经阅读了类似的问题SPARQL selecting MAX value of a counter，但我还没有。

考虑到这些三元组：

@prefix turbo: <http://example.org/ontologies/> .
@prefix xsd: <http://www.w3.org/2001/XMLSchema#> .

<http://example.org/ontologies/b6be95364ec943af2ef4ab161c11c855>
  a <http://example.org/ontologies/StudyPartWithBBDonation> ;
  turbo:hasBirthDateO turbo:3950b2b6-f575-4074-b0e8-f9fa3378f3be, turbo:4250aafa-4b0c-4f73-92b6-7639f427b61d, turbo:a3e6676e-a214-4af4-b8ef-34a8e20170bf .

turbo:3950b2b6-f575-4074-b0e8-f9fa3378f3be turbo:hasDateValue "1971-12-30"^^xsd:date .
turbo:4250aafa-4b0c-4f73-92b6-7639f427b61d turbo:hasDateValue "1971-12-30"^^xsd:date .
turbo:a3e6676e-a214-4af4-b8ef-34a8e20170bf turbo:hasDateValue "1971-12-30"^^xsd:date .
turbo:6e200ca0d5150282787464a2bda55814
  a turbo:StudyPartWithBBDonation ;
  turbo:hasBirthDateO turbo:b09519f5-b123-40d5-bb4a-737ec9f8b9a8, turbo:06c56881-a6c7-4d1d-993b-add8862dffd7, turbo:12ef184d-c8d6-4d93-a558-a3ba47bb56ca .

turbo:b09519f5-b123-40d5-bb4a-737ec9f8b9a8 turbo:hasDateValue "2000-04-04"^^xsd:date .
turbo:06c56881-a6c7-4d1d-993b-add8862dffd7 turbo:hasDateValue "2000-04-04"^^xsd:date .
turbo:12ef184d-c8d6-4d93-a558-a3ba47bb56ca turbo:hasDateValue "2000-04-05"^^xsd:date .

此查询

PREFIX  turbo: <http://example.org/ontologies/>
SELECT  ?part ?xsddate (COUNT(?xsddate) AS ?datecount) 
  { ?part  rdf:type             turbo:StudyPartWithBBDonation ;
           turbo:hasBirthDateO  ?dob .
    ?dob   turbo:hasDateValue   ?xsddate
  }
GROUP BY ?part ?xsddate

给出以下内容：

+----------------------------------------+------------------------+------------------+
|                  part                  |        xsddate         |    datecount     |
+----------------------------------------+------------------------+------------------+
| turbo:6e200ca0d5150282787464a2bda55814 | "2000-04-05"^^xsd:date | "1"^^xsd:integer |
| turbo:b6be95364ec943af2ef4ab161c11c855 | "1971-12-30"^^xsd:date | "3"^^xsd:integer |
| turbo:6e200ca0d5150282787464a2bda55814 | "2000-04-04"^^xsd:date | "2"^^xsd:integer |
+----------------------------------------+------------------------+------------------+

我只想查看参与研究的每位患者的最高计数日期：

+----------------------------------------+------------------------+------------------+
|                  part                  |        xsddate         |    datecount     |
+----------------------------------------+------------------------+------------------+
| turbo:b6be95364ec943af2ef4ab161c11c855 | "1971-12-30"^^xsd:date | "3"^^xsd:integer |
| turbo:6e200ca0d5150282787464a2bda55814 | "2000-04-04"^^xsd:date | "2"^^xsd:integer |
+----------------------------------------+------------------------+------------------+

我想我在这里越来越近了。现在我需要在同一行获得计数和最大计数！

PREFIX  rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX  turbo: <http://example.org/ontologies/>

SELECT  ?part ?xsddate ?datecount ?countmax
WHERE
  {   { SELECT  ?part ?xsddate (COUNT(?xsddate) AS ?datecount)
        WHERE
          { ?part  rdf:type             turbo:StudyPartWithBBDonation ;
                   turbo:hasBirthDateO  ?dob .
            ?dob   turbo:hasDateValue   ?xsddate
          }
        GROUP BY ?part ?xsddate
      }
    UNION
      { SELECT  ?part (MAX(?datecount) AS ?countmax)
        WHERE
          { SELECT  ?part ?xsddate (COUNT(?xsddate) AS ?datecount)
            WHERE
              { ?part  rdf:type             turbo:StudyPartWithBBDonation ;
                       turbo:hasBirthDateO  ?dob .
                ?dob   turbo:hasDateValue   ?xsddate
              }
            GROUP BY ?part ?xsddate
          }
        GROUP BY ?part
      }
  }

给

+----------------------------------------+------------------------+------------------+------------------+
|                  part                  |        xsddate         |    datecount     |     countmax     |
+----------------------------------------+------------------------+------------------+------------------+
| turbo:6e200ca0d5150282787464a2bda55814 | "2000-04-05"^^xsd:date | "1"^^xsd:integer |                  |
| turbo:b6be95364ec943af2ef4ab161c11c855 | "1971-12-30"^^xsd:date | "3"^^xsd:integer |                  |
| turbo:6e200ca0d5150282787464a2bda55814 | "2000-04-04"^^xsd:date | "2"^^xsd:integer |                  |
| turbo:6e200ca0d5150282787464a2bda55814 |                        |                  | "2"^^xsd:integer |
| turbo:b6be95364ec943af2ef4ab161c11c855 |                        |                  | "3"^^xsd:integer |
+----------------------------------------+------------------------+------------------+------------------+

Answer 1

基本上，您只需要在查询中将UNION替换为.（或者您可以删除此UNION，正如@AKSW在下面的评论中指出的那样。）< / p>

然而，在GraphDB中，您将收到错误：

变量?datecount已在之前的投影中使用过。绑定自从Sesame 2.8以来没有通过投影传播，所以这可能导致查询中的逻辑错误。

因此，以这种方式更改您的查询：

PREFIX  rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX  turbo: <http://example.org/ontologies/>

SELECT  ?part ?xsddate ?datecount_ ?countmax
WHERE
  {   { SELECT  ?part ?xsddate (COUNT(?xsddate) AS ?datecount_)
        WHERE
          { ?part  rdf:type             turbo:StudyPartWithBBDonation ;
                   turbo:hasBirthDateO  ?dob .
            ?dob   turbo:hasDateValue   ?xsddate
          }
        GROUP BY ?part ?xsddate
      }
      .
      { SELECT  ?part (MAX(?datecount) AS ?countmax)
        WHERE
          { SELECT  ?part ?xsddate (COUNT(?xsddate) AS ?datecount)
            WHERE
              { ?part  rdf:type             turbo:StudyPartWithBBDonation ;
                       turbo:hasBirthDateO  ?dob .
                ?dob   turbo:hasDateValue   ?xsddate
              }
            GROUP BY ?part ?xsddate
          }
        GROUP BY ?part
      }
  }

在Blazegraph中，您可以使用named subqueries：

PREFIX  rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX  turbo: <http://example.org/ontologies/>

SELECT  ?part ?xsddate ?datecount ?countmax

WITH 
  { SELECT  ?part ?xsddate (COUNT(?xsddate) AS ?datecount)
      WHERE
        { ?part  rdf:type             turbo:StudyPartWithBBDonation ;
                 turbo:hasBirthDateO  ?dob .
          ?dob   turbo:hasDateValue   ?xsddate
        }
       GROUP BY ?part ?xsddate
  } AS %sub

WHERE
  {  { SELECT ?part (MAX(?datecount) AS ?countmax)
       WHERE { INCLUDE %sub } GROUP BY ?part
     }
      INCLUDE %sub
  }

Answer 2

我对斯坦尼斯拉夫的精彩答案的阐述

以其中一个?datecount模式

{}

添加了过滤器
将共识DOB插入三元组中的命名图

PREFIX  rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX  turbo: <http://example.org/ontologies/>

INSERT {
  GRAPH turbo:DOB_conclusions {
    ?part turbo:hasBirthDateO ?DOBconc .
    ?DOBconc turbo:hasDateValue ?xsddate .
    ?DOBconc turbo:conclusionated true .
    ?DOBconc rdf:type <http://www.ebi.ac.uk/efo/EFO_0004950> .
  }
}
WHERE
  { { SELECT  ?part ?xsddate (COUNT(?xsddate) AS ?datecount)
      WHERE
        { ?part  rdf:type             turbo:StudyPartWithBBDonation ;
                 turbo:hasBirthDateO  ?dob .
          ?dob   turbo:hasDateValue   ?xsddate
        }
      GROUP BY ?part ?xsddate
    }
    .
    { SELECT  ?part (MAX(?datecount2) AS ?countmax)
      WHERE
        { SELECT  ?part ?xsddate (COUNT(?xsddate) AS ?datecount2)
          WHERE
            { ?part  rdf:type             turbo:StudyPartWithBBDonation ;
                     turbo:hasBirthDateO  ?dob .
              ?dob   turbo:hasDateValue   ?xsddate
            }
          GROUP BY ?part ?xsddate
        }
      GROUP BY ?part
    }
    FILTER ( ?datecount = ?countmax )
    BIND(uri(concat("http://transformunify.org/ontologies/", struuid())) AS ?DOBconc)
  }

选择组中最常出现的值

2 个答案: