Question

我正在使用Excel VBA创建广告资源管理工具。我已创建代码，从Internet Explorer的下拉框中收集名称列表，并将它们放入数组中。

我需要做的是与vba create several textboxes comboboxes dynamically in userform类似，但我会动态地为用户名和文本框添加标签，以获取每个人将接收的FLN数量。然后，这些将进入我已创建的预定义用户表单。

根据上面的代码示例，我意识到我无法使用.Name = "Textbox" & i重命名下一个标签或文本框。 i必须等于一个不断变化的清单，所以它不能一成不变;因此，为什么必须有与UBound(UserArray)一样多的标签和文本框。

已更新

Private Sub CreateControl()
    Dim newTxt As msforms.Control, newLbl
    Dim i As Integer, TopAmt
    Dim UserArray As String

    TopAmt = 30

    For i = LBound(MyArray) + 1 To UBound(MyArray) - 1
        Set newLbl = MultipleOptionForm.Controls.Add("Forms.Label.1")
        With newLbl
            .Name = "Label" & i
            .Left = 10
            .Top = TopAmt
            .WordWrap = False
            .AutoSize = True
            .Visible = True
            .Caption = MyArray(i)
            Debug.Print .Name,
        End With

        Set newTxt = MultipleOptionForm.Controls.Add(bstrProgID:="Forms.Textbox.1", Name:="Textbox" & i)
        With newTxt
            .Left = 150
            .Top = TopAmt
            .Visible = True
            .Width = 20
            Debug.Print .Name
        End With
        TopAmt = TopAmt + newTxt.Height
    Next

    MultipleOptionForm.Show
End Sub

Answer 1

娄这个问题的答案是误导性的。通过更改其ProgID来添加控件时，问题想要提供默认名称（bstrProgID是一个引用要创建的类的字符串）。

如果另一个控件的名称不同，您可以重命名新控件。

您还可以将控件名称作为参数传递给Controls.Add方法。

您的标签未显示是您从未设置Label.Caption值。

Private Sub CreateControl()
    Dim newLbl As MSForms.Label
    Dim newTxt As MSForms.Control
    Dim i As Integer, TopAmt
    Dim UserArray As Variant

    TopAmt = 50
    UserArray = Array("Cat", "Dog", "Horse", "Gorrilla")

    For i = LBound(UserArray) To UBound(UserArray)
        Set newLbl = MultipleOptionForm.Controls.Add("Forms.Label.1")
        With newLbl
            .Name = "Label" & i
            .Left = 50
            .Top = TopAmt
            .Visible = True
            .Caption = UserArray(i)
            Debug.Print .Name,
        End With

        Set newTxt = MultipleOptionForm.Controls.Add(bstrProgID:="Forms.Textbox.1", Name:="Textbox" & i)
        With newTxt
            .Left = 100
            .Top = TopAmt
            .Visible = True
            Debug.Print .Name
        End With
        TopAmt = TopAmt + newTxt.Height
    Next
End Sub

下一期：如何从这些动态创建的文本框中获取数据？

Dim newTxt As MSForms.Control
For i = LBound(UserArray) To UBound(UserArray)
    set newTxt  =  MultipleOptionForm.Controls("Textbox" & i)
    If UserArray(i) <> newTxt.Value then
        'Do something
    End if
Next

在运行时使用vba将多个标签和文本框添加到Excel用户表单

1 个答案:

下一期：如何从这些动态创建的文本框中获取数据？