Question

我在一个查询中创建多个关系。如果未找到第一个关系的匹配，则不会创建第二个关系。如果两个匹配都存在，则两个关系都有效

示例：

假设＆＃39; MATCH1ID＆＃39;以下不存在但是＆＃39; MATCH2ID＆＃39;确实。为什么会这样？

不工作

MERGE (NewRecord:OBJECTNAME { Id: 'ABZDEFG' })
SET NewRecord.name='NEWNAME'
WITH NewRecord
MATCH (a)
WHERE a.Id = 'MATCH1ID'
CREATE (a)-[ar:Relationship1]->(NewRecord)
WITH NewRecord MATCH (b)
WHERE b.Id = 'MATCH2ID'
CREATE (b)-[br:Relationship2]->(NewRecord)

（如果我按照它的工作顺序切换存在的节点的顺序）

WORKS

MERGE (NewRecord:OBJECTNAME { Id: 'ABZDEFG' })
SET NewRecord.name='NEWNAME'
WITH NewRecord
MATCH (b)
WHERE b.Id = 'MATCH2ID'
CREATE (b)-[br:Relationship2]->(NewRecord)
WITH NewRecord
MATCH (a)
WHERE a.Id = 'MATCH1ID'
CREATE (a)-[ar:Relationship1]->(NewRecord)

Answer 1

您可以尝试使用OPTIONAL MATCH而不是简单的MATCH：

MERGE (NewRecord:OBJECTNAME { Id: 'ABZDEFG' })
SET NewRecord.name='NEWNAME'
WITH NewRecord
OPTIONAL MATCH (a)
WHERE a.Id = 'MATCH1ID'

FOREACH(x IN (CASE WHEN a IS NULL THEN [] ELSE [1] END) | 
    CREATE (a)-[ar:Relationship1]->(NewRecord)
)

WITH NewRecord
OPTIONAL MATCH (b)
WHERE b.Id = 'MATCH2ID'

FOREACH(x IN (CASE WHEN b IS NULL THEN [] ELSE [1] END) | 
    CREATE (b)-[br:Relationship2]->(NewRecord) 
)

此外，此查询使用FORACH和CASE WHEN的技巧来处理条件。在这种情况下，CREATE语句仅在a或b变量不为空时执行。

请参阅Neo4j: LOAD CSV - Handling Conditionals。

Neo4j：创建多个关系不起作用

1 个答案: