Question

我声明了以下新类型：

newtype Code = Code String deriving (Show)
newtype Name = Name String deriving (Show)
newtype Account = Account (Code, Name) deriving (Show)

所以：

*Main Lib> :t Code
Code :: String -> Code
*Main Lib> :t Name
Name :: String -> Name
*Main Lib> :t Account
Account :: (Code, Name) -> Account

然后我创建了一些实例：

cn = Code "1.1.1"
nn = Name "Land And Buildings"
an = Account (cn, nn)

*Main Lib> an
Account (Code "1.1.1",Name "Land And Buildings")

现在我需要访问变量Code中的an字段，例如an.Code我该怎么做？

使用Data代替newtype会更好吗？如果Haskell允许我创建一个名为tuple的新类型，那么我想应该有一种简单的方法来访问里面的元素。

Answer 1

使用data代替newtype？
是否更好？

嗯，是的...... newtype的重点是给单类型一个新名称。它不应该用于构建复合类型。因此，与user2407038建议一样，将其设为

data Account = Account
    { accCode :: Code
    , accName :: Name
    } deriving (Show)

然后你可以简单地使用

*Main Lib> let an = Account (Code "1.1.1") (Name "Land And Buildings")
*Main Lib> accCode an
Code "1.1.1"

也就是说，如果你给newtype打开一个unwrapper，那么访问一个埋在newtype中的元组中的字段也不难：

newtype Account = Account {getAccount :: (Code, Name)}
   deriving (Show)

然后

*Main Lib> let an = Account (Code "1.1.1", Name "Land And Buildings")
*Main Lib> fst $ getAccount an
Code "1.1.1"

如果你想要花哨，你也可以使用“20.2世纪记录访问者”，lenses：

{-# LANGUAGE TemplateHaskell, FunctionalDependencies #-}
import Lens.Micro
import Lens.Micro.TH

data Account = Account
    { accountCode :: Code
    , accountName :: Name
    } deriving (Show)
makeFields ''Account

然后

*Main Lib> let an = Account (Code "1.1.1") (Name "Land And Buildings")
*Main Lib> an^.code
Code "1.1.1"

Answer 2

您可以使用模式匹配。 E.g。

case an of
  Account (Code c, Name n) -> "Code " ++ c ++ ", Name " ++ n

或者，在函数定义中，您可以直接编写

foo :: Account -> String
foo  (Account (Code c, Name n)) = "Code " ++ c ++ ", Name " ++ n

使用data通常会更好。

data Account = Account Code Name
-- ...
case an of
  Account (Code c) (Name n) -> "Code " ++ c ++ ", Name " ++ n

如何在haskell

2 个答案: