Question

我想创建一个vbs文件，提醒我每隔1小时休息一下。它应该打开一个新窗口，其中包含＆＃34;时间进行小休息＆＃34;作为消息。我会一直运行脚本。它只需要每隔1小时打开一个小消息框，并在30秒后关闭消息框。我想知道我是否可以使用时间而不是使用大循环。感谢帮助。

Answer 1

试试这个批处理文件，创建一个每小时执行一次的预定vbscript文件： Create_scheduled_Vbscript.bat

@echo off
color 0A & Mode 80,5
Title Create a scheduled vbscript file to be executed every hour
set "VBSFilePath=c:\Msg.vbs"
set "TaskName=BreakTime"
:CreateVBSFile
(
    echo strText = "Time for a small break !"
    echo set ws=CreateObject("wscript.shell"^)
    echo ws.Popup strText,30,strText,vbInformation 
)>"%VBSFilePath%"
Rem 60 minutes = 1Hour
Call :Create_Schedule_Task 60 "%TaskName%" "%VBSFilePath%"
Rem Just to query the BreakTime TaskName
Schtasks /Query /TN "%TaskName%" | find /i "%TaskName%"
pause & exit
::***********************************************************************
:Create_Schedule_Task <Repeat_Task_Every(N)Minute> <TaskName> <FilePath>
Schtasks /create /SC minute /MO %1 /TN "%~2" /TR "%~3"
exit /b
::***********************************************************************

如果您因任何原因想要删除此TaskName = BreakTime

只需执行此小批量文件： Delete_Taskname.bat

@echo off
set "TaskName=BreakTime"
SCHTASKS /DELETE /TN "%TaskName%" /F
pause

如何使用vbscript创建定时消息？

1 个答案: