宏和/或宏字符

Question

我正在使用cl-who来生成svg，并且它正常工作直到我需要一个混合大小写标记：

(with-html-output (*standard-output*)
  (:defs
    (:|radialGradient| :id "grad1" :cy "20" :fx "10%" :fy "50%" :r "8"
      (:stop :offset "0%" :stop-color "#fff")
      (:stop :offset "100%" :stop-color "#000"))))

对于这种情况，有一个变量* downcase-tokens-p *。它有点难以使用：

(let ((*downcase-tokens-p* nil))
  (with-html-output (*standard-output*)
    (:defs
        (:|radialGradient| :id "grad1" :cy "20" :fx "10%" :fy "50%" :r "8"))))

输出：

<defs>
  <radialgradient id='grad1' cy='20' fx='10%' fy='50%' r='8'>
  </radialgradient>
</defs>

使用let包装无效，因为* downcase-tokens-p *在宏扩展时显然设置为T.

所以我们需要拖出eval：

(let ((*downcase-tokens-p* nil))
  (eval
  '(with-html-output (*standard-output*)
    (:defs
      (:|radialGradient| :id "grad1" :cy "20" :fx "10%" :fy "50%" :r "8")))))

输出：

<DEFS>
  <radialGradient ID='grad1' CY='20' FX='10%' FY='50%' R='8'>
  </radialGradient>
</DEFS>

这适用于radialGradient标记，但现在我需要||包装其他一切。

让radialGradient标记正确显示的最简单方法是什么？留下其他所有内容？

编辑：添加了示例。

Answer 1

覆盖单个标记的呈现方法：

(defmethod convert-tag-to-string-list ((tag (eql :radialgradient))
                                       attr-list body body-fn)
  (nconc (cons "<radialGradient"
               (convert-attributes attr-list))
         (list ">")
         (funcall body-fn body)
         (list "</radialGradient>")))

删除了|

(with-html-output (*standard-output*)
  (:defs
      (:radialGradient :id "grad1" :cy "20" :fx "10%" :fy "50%" :r "8")))

输出：

<defs>
  <radialGradient id='grad1' cy='20' fx='10%' fy='50%' r='8'
  </radialGradient>
</defs>

需要为正在使用的每个混合大小写SVG标记定义convert-tag-to-string-list方法。

Answer 2

这是一个通用的解决方案：

(defmethod convert-tag-to-string-list :around ((tag t) attr-list body body-fn)
  (if (find-if #'lower-case-p (symbol-name tag))
      (nconc (list* "<"
                    (symbol-name tag)
                    (convert-attributes attr-list))
             (list ">")
             (funcall body-fn body)
             (list (format nil "</~a>" (symbol-name tag))))
      (call-next-method)))

结果：

CL-USER> (with-html-output (*standard-output*)
           (:asdf
            (:ASDF
             (:|aSDf|
               (:|ASDF|)))))
<asdf><asdf><aSDf><asdf></asdf></aSDf></asdf></asdf>

Answer 3

你可以改变Lisp读者的情况。

PRESERVE

(setf (readtable-case *readtable*) :preserve)

从现在开始，所有CL符号必须以大写字母书写，但您只能在需要读取SVG树的文件中使用named-readtables进行本地化更改。

(DEFPACKAGE :TWHO (:USE :CL :CL-WHO))
(IN-PACKAGE :TWHO)

(SETF *DOWNCASE-TOKENS-P* NIL)

(WITH-HTML-OUTPUT (*STANDARD-OUTPUT* *STANDARD-OUTPUT* :INDENT T)
  (:defs
    (:radialGradient :id "grad1" :cy "20" :fx "10%" :fy "50%" :r "8"
      (:stop :offset "0%" :stop-color "#fff")
      (:stop :offset "100%" :stop-color "#000"))))

写下以下内容：

<defs>
  <radialGradient id='grad1' cy='20' fx='10%' fy='50%' r='8'>
    <stop offset='0%' stop-color='#fff'></stop>
    <stop offset='100%' stop-color='#000'></stop>
  </radialGradient>
</defs>

INVERT

我个人使用:invert，但在这种情况下，你必须用大写字母写下所有小写的SVG符号。

(SETF (READTABLE-CASE *READTABLE*) :INVERT)

(with-html-output (*standard-output* *standard-output* :indent t)
  (:DEFS
    (:radialGradient :ID "grad1" :CY "20" :FX "10%" :FY "50%" :R "8"
      (:STOP :OFFSET "0%" :STOP-COLOR "#fff")
      (:STOP :OFFSET "100%" :STOP-COLOR "#000"))))

写同样的事情：

<defs>
  <radialGradient id='grad1' cy='20' fx='10%' fy='50%' r='8'>
    <stop offset='0%' stop-color='#fff'></stop>
    <stop offset='100%' stop-color='#000'></stop>
  </radialGradient>
</defs>"

但至少你的CL代码不需要用大写字母写。

宏和/或宏字符

您可以使用宏和宏字符进行本地更改。

将所有内容重置为默认值：

(setf *downcase-tokens-p* t)
(setf (readtable-case *readtable*) :upcase)

我个人不介意在全局范围内更改*downcase-tokens-p*，但如果您真的想要，除了使用eval之外的另一种方法是手动宏扩展。对于此示例，我使用 macroexpand-dammit ：

(ql:quickload "macroexpand-dammit")

然后，您定义一个自定义宏：

(defmacro with-svg-output ((stream) &body body)
  (let ((*downcase-tokens-p* nil))
    (let ((stream% (copy-symbol :stream)))
      (macroexpand-dammit:macroexpand-dammit 
       `(let ((,stream% ,stream))
          (with-html-output (,stream% ,stream% :indent t)
            ,@body))))))

最后，只有在读取SVG表单时才更改readtable的大小写，请定义自定义读取器功能;我将它绑定到#@字符序列：

(set-dispatch-macro-character
 #\# #\@
 (lambda (stream &rest args)
   (declare (ignore args))
   (let ((*readtable* (copy-readtable)))
     (setf (readtable-case *readtable*) :invert)
     (read stream t nil t))))

该示例可以重写为：

(with-svg-output (*standard-output*)
  #@(:DEFS
      (:radialGradient :ID "grad1" :CY "20" :FX "10%" :FY "50%" :R "8"
        (:STOP :OFFSET "0%" :STOP-COLOR "#fff")
        (:STOP :OFFSET "100%" :STOP-COLOR "#000"))))

这里的优点是您的更改仅在本地应用，并且有一种非常独特的语法，表示存在不同的情况。如果您可以在SVG表达式中以大写编写代码，那么您可以使用:preserve代替。这取决于什么对你更方便。

Answer 4

从cl-who-20190710-git开始，默认情况下，它保留大小写混合的关键字作为标记名，因此可以在不添加任何宏/方法的情况下使用它们：

 (htm 
   (:|clipPath| :x 0 :y 0 ...))

有* downcase-tokens-p *选项进行配置。

cl-who中的混合大小写标记名称

4 个答案:

PRESERVE

INVERT

宏和/或宏字符