从EG获取SAS VA报告创建者的名称（元数据）

Question

我正在尝试访问SAS VA中报告的创建者（或上次更新报告的人）的名称，而无需检查服务器上的物理文件的创建者，这些文件对我来说是无法访问的。这种数据是否存储在METADATA中？

我使用％MDSECDS宏来访问元数据，自动创建的MDSECDS_OBJS表包含我需要的大部分数据，但报告的创建者不在其中。

有没有办法访问该人的姓名，创建或更新报告的人是SAS VA（使用EG获取报告会很棒）？

谢谢！

Answer 1

是的，它可能。

%let report_name=NAME_OF_REPORT;

data report_info;
    length uri  Respuri 
        $256 
        Date
        Name
        Role
        $40
    ;
    n_rep=metadata_getnobj("omsobj:Transformation?@Name contains '&report_name'",1,uri);

    do iter_rep=1 to n_rep;
        rc=metadata_getattr(uri, "MetadataCreated", Date);
        passn=metadata_getnasn(uri,"ResponsibleParties",1,Respuri);
        rc=metadata_getattr(Respuri, "Role", Role);
        rc=metadata_getattr(Respuri, "Name", Name);
        output;
        rc=metadata_getattr(uri, "MetadataUpdated", Date);
        passn=metadata_getnasn(uri,"ResponsibleParties",2,Respuri);
        rc=metadata_getattr(Respuri, "Role", Role);
        rc=metadata_getattr(Respuri, "Name", Name);
        output;
    end;

    keep date name role;
run;

返回

+--------------------+-------------+-------------+
|        Date        |    Name     |    Role     |
+--------------------+-------------+-------------+
| 19Jun2017:13:24:18 | UserName1   | Created By  |
| 26Jul2017:11:28:07 | UserName2   | Modified By |
+--------------------+-------------+-------------+

此外，您可以使用SAS Metadata Browser查看所有元对象。

  

sas.exe - ＆gt; ＆＃34;解＆＃34;标签 - ＆gt;配件 - ＆gt;元数据浏览器