Question

我想用较小的模块组成一个模块。

这是我现在的模块：

defmodule Api.Product do
  use Ecto.Schema
  import Ecto.Changeset
  import Api.Repo
  import Ecto.Query

  @derive {Poison.Encoder, only: [:name, :brand, :description, :image, :rating, :number_of_votes]}
  schema "products" do
    field :name, :string
    field :brand, :string
    field :description, :string
    field :image, :string
    field :rating, :integer
    field :number_of_votes, :integer
    field :not_vegan_count, :integer
  end

  def changeset(product, params \\ %{}) do
    product
    |> cast(params, [:name, :brand, :description, :image, :rating, :number_of_votes, :not_vegan_count])
    |> validate_required([:name, :description, :brand])
    |> unique_constraint(:brand, name: :unique_product)
  end

  def delete_all_from_products do
    from(Api.Product) |> delete_all
  end

  def insert_product(conn, product) do
    changeset = Api.Product.changeset(%Api.Product{}, product)
    errors = changeset.errors
    valid = changeset.valid?
    case insert(changeset) do
      {:ok, product} ->
        {:success, product}
      {:error, changeset} ->
        {:error, changeset}
    end
  end

  def get_product_by_name_and_brand(name, brand) do
    Api.Product |> Ecto.Query.where(name: ^name) |> Ecto.Query.where(brand: ^brand) |> all
  end

  def get_products do
    Api.Product |> all
  end
end

但除了Product之外，我希望除Product以外的其他内容与brand具有大部分相同的字段。因此，最好创建一个包含除brand之外的所有字段的模块，然后包含这些字段的所有模块都将该模块作为字段？

这是我的模块，所有模块都包含：

defmodule Api.VeganThing do
  use Ecto.Schema
  import Ecto.Changeset
  import Api.Repo
  import Ecto.Query

  @derive {Poison.Encoder, only: [:name, :description, :image, :rating, :number_of_votes]}
  schema "vegan_things" do
    field :name, :string
    field :description, :string
    field :image, :string
    field :rating, :integer
    field :number_of_votes, :integer
    field :not_vegan_count, :integer
  end
end

vegan_things没有数据库表。但是一些具有数据库表的不同模块将包含vegan_thing。

这是避免重写Elix中每个模块中每个字段的代码重复的好方法吗？

这是我目前的变更集：

defmodule Api.Repo.Migrations.CreateProducts do
  use Ecto.Migration

  def change do
    create table(:products) do
      add :name, :string
      add :brand, :string
      add :description, :string
      add :image, :string
      add :rating, :integer
      add :number_of_votes, :integer
      add :not_vegan_count, :integer
    end

    create unique_index(:products, [:name, :brand], name: :unique_product)
  end
end

所以我基于vegan_thing字段中的唯一性以及仅product中的字段。我可以这样做吗？

defmodule Api.Repo.Migrations.CreateProducts do
  use Ecto.Migration

  def change do
    create table(:products) do
      add :name, :string
      add :vegan_thing, :vegan_thing
    end

    create unique_index(:products, [:vegan_thing.name, :brand], name: :unique_product)
  end
end

或者我是否必须将name字段直接放在product中？而不是vegan_thing能够将其用作唯一约束吗？

Answer 1

宏可以用于这种情况：

  defmodule Vegan do
    defmacro vegan_schema name, fields do
      quote do
        schema unquote(name) do
          unquote(fields)
          field :name, :string
          field :description, :string
          field :image, :string
          field :rating, :integer
          field :number_of_votes, :integer
          field :not_vegan_count, :integer
        end
      end
    end

    def changeset(struct_or_changeset, params) do
      struct_or_changeset
      |> Ecto.Changeset.cast(params, [:name, :description, :rating])
      |> Ecto.Changeset.validate_required([:name, :description])
    end
  end

  defmodule Product do
    use Ecto.Schema
    require Vegan

    @derive {Poison.Encoder, only: [:name, :brand, :description, :image, :rating, :number_of_votes]}
    Vegan.vegan_schema "products" do
      field :brand, :string
    end

    def changeset(params) do
      %Product{}
      |> Vegan.changeset(params)
      |> Ecto.Changeset.cast(params, [:brand])
      |> Ecto.Changeset.validate_required([:brand])
    end
  end

对于处理Ecto.Changeset的其他函数，那么常规模块和函数应该可以用于分解任何重复的代码，如上面的示例所示Product.changeset/1调用Vegan.changeset/2来强制转换验证公共领域。

Elixir和Ecto中的代码重复

1 个答案: