如何使用GLSL着色器将径向模糊应用于整个场景？

Question

我在GLSL中有一个径向模糊着色器，它采用纹理，对其应用径向模糊并将结果呈现给屏幕。到目前为止，这非常有效。

问题是，这会将径向模糊应用于场景中的第一个纹理。但我真正想做的是将此模糊应用于整个场景。

实现此功能的最佳方法是什么？我是否可以仅使用着色器执行此操作，或者是否必须首先将场景渲染到纹理（在OpenGL中），然后将此纹理传递到着色器以进行进一步处理？

// Vertex shader

varying vec2 uv;

void main(void)
{
    gl_Position = vec4( gl_Vertex.xy, 0.0, 1.0 );
    gl_Position = sign( gl_Position );
    uv = (vec2( gl_Position.x, - gl_Position.y ) + vec2(1.0) ) / vec2(2.0);
}

// Fragment shader

uniform sampler2D tex;
varying vec2 uv;
const float sampleDist = 1.0;
const float sampleStrength = 2.2; 

void main(void)
{
    float samples[10];
    samples[0] = -0.08;
    samples[1] = -0.05;
    samples[2] = -0.03;
    samples[3] = -0.02;
    samples[4] = -0.01;
    samples[5] =  0.01;
    samples[6] =  0.02;
    samples[7] =  0.03;
    samples[8] =  0.05;
    samples[9] =  0.08;

    vec2 dir = 0.5 - uv; 
    float dist = sqrt(dir.x*dir.x + dir.y*dir.y); 
    dir = dir/dist; 

    vec4 color = texture2D(tex,uv); 
    vec4 sum = color;

    for (int i = 0; i < 10; i++)
        sum += texture2D( tex, uv + dir * samples[i] * sampleDist );

    sum *= 1.0/11.0;
    float t = dist * sampleStrength;
    t = clamp( t ,0.0,1.0);

    gl_FragColor = mix( color, sum, t );
}

Answer 1

这基本上被称为“后期处理”，因为你在渲染之后将效果（这里是：径向模糊）应用于整个场景。

所以是的，你是对的：后处理的好方法是：

• 创建屏幕大小的NPOT纹理（GL_TEXTURE_RECTANGLE），
• 创建一个FBO，将纹理附加到它
• 将此FBO设置为活动状态，渲染场景
• 禁用FBO，使用FBO的纹理绘制全屏四边形。

---

至于“为什么”，原因很简单：场景是并行渲染的（片段着色器是针对许多像素独立执行的）。为了对像素（x，y）进行径向模糊，首先需要知道周围像素的预模糊像素值。并且这些在第一遍中不可用，因为它们仅在此期间被渲染。

因此，您必须仅在渲染整个场景后应用径向模糊，并且片段（x，y）的片段着色器能够从场景中读取任何像素。这就是为什么你需要2个渲染阶段的原因。