Question

所以基本上当用户点击复选框时，我想在我的列表中添加该项，我尝试使用OnChange事件，但这对我不起作用，因为即使没有单击Checkbox也会被触发。< / p>

我的代码简单明了

procedure LvUserChange(Sender: TObject; Item: TListItem;Change: TItemChange);
 var
 objUser : TUsers;
begin
   if not assigned(objListOfChangedUsers) then
   objListOfChangedUsers := TObjectList.Create;

   objUser := Item.Data;
   objListOfChangedUsers.Add(objUser);
end;

我希望仅在ListView

中单击复选框时才会触发此代码

Answer 1

在Delphi 2009及更高版本中，您可以使用TListView.OnItemChecked事件来检测复选框点击。 Delphi 2007没有这样的事件，在这种情况下，您需要在自己的代码中手动检测通知。我将使用插入器类演示，但还有其他方法可以做到这一点。

uses
  ..., CommCtrl, ComCtrls, ...;

type
  TListView = class(ComCtrls.TListView)
  protected
    procedure CNNotify(var Message: TWMNotifyLV); message CN_NOTIFY;
  end;

....

procedure TListView.CNNotify(var Message: TWMNotifyLV);
begin
  inherited;
  if Message.NMHdr.code = LVN_ITEMCHANGED then
  begin
    if (Message.NMListView.uChanged = LVIF_STATE) and
       ( ((Message.NMListView.uOldState and LVIS_STATEIMAGEMASK) shr 12)
         <> ((Message.NMListView.uNewState and LVIS_STATEIMAGEMASK) shr 12)) then
    begin
      // changing check box state will land you here
    end;
  end;
end;

Answer 2

由于OnItemChecked不存在，因此只有在选中该项时才能触发您的事件，但您可以像这样过滤您的事件

procedure LvUserChange(Sender: TObject; Item: TListItem;Change: TItemChange);
 var
 objUser : TUsers;
begin
   if Change = ctState then
   begin
     if Item.Checked then
     begin
       if not assigned(objListOfChangedUsers) then
       objListOfChangedUsers := TObjectList.Create;

       objUser := Item.Data;
       objListOfChangedUsers.Add(objUser);
     end
     else
     begin
       // just in case there are any actions when unchecking
     end;
   end;
end;

我没有Delphi 2007，但已经检查了文档，它应该可以工作。

如何在TListView中检测CheckBox上的单击

2 个答案: