Question

当输出文件有重复的URI时，有没有办法让xsl：result-document覆盖或跳过文件？我想我不必提供一个例子。我有数据库，里面有重复的条目。我知道我可以输入一个id，然后从60000个文件的名称中删除id

最好的问候。

Answer 1

在XSLT 3.0中，您可以使用xsl:try/xsl:catch捕获错误以写入输出URI两次，给定样式表

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:math="http://www.w3.org/2005/xpath-functions/math"
    xmlns:err="http://www.w3.org/2005/xqt-errors"
    exclude-result-prefixes="xs math"
    version="3.0">

    <xsl:mode streamable="yes"/>

    <xsl:output method="text"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/">
        <xsl:apply-templates select="copy-of(root/record)" mode="result"/>
    </xsl:template>

    <xsl:template match="record" mode="result">
        <xsl:try>
            <xsl:result-document href="{fname}.txt" method="text">
                <xsl:value-of select="* except fname" separator=","/>
            </xsl:result-document>
            <xsl:catch errors="err:XTDE1490">
                <xsl:message select="'Attempt to write more than once to ', fname"/>
            </xsl:catch>
        </xsl:try>
    </xsl:template>

</xsl:stylesheet>

和

之类的输入

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <record>
        <fname>result1</fname>
        <foo>1</foo>
        <bar>a</bar>
    </record>
    <record>
        <fname>result2</fname>
        <foo>2</foo>
        <bar>b</bar>
    </record>
    <record>
        <fname>result1</fname>
        <foo>1</foo>
        <bar>a</bar>
    </record>
</root>

Saxon 9.8 EE使用流处理输入并写入两个结果文件，同时在处理第三个记录时尝试再次写入result1.txt时捕获错误。

关于@MichaelKay关于将要捕获哪些重复项的实现依赖性的评论，我同意这一点，但如果要避免这种情况，那么我们可以简单地替换

<xsl:template match="/">
    <xsl:apply-templates select="copy-of(root/record)" mode="result"/>
</xsl:template>

使用xsl:iterate

<xsl:template match="/">
    <xsl:iterate select="root/record">
       <xsl:apply-templates select="copy-of()" mode="result"/>
    </xsl:iterate>
</xsl:template>

这种方式我认为顺序处理已经完成。

Answer 2

您可以与Saxon一起使用的技巧是通过添加查询部分href="{fname}.txt?n={position()}来使URI唯一，然后在OutputURIResolver中将其删除。

xslt结果文档覆盖或跳过具有重复uri的文件

2 个答案: