Question

我试图压扁以下XML：

<?xml version="1.0" encoding="utf-8"?>
<root xmlns="http://pretend.namespace">
    <record>
        <first>1</first>
        <second>2</second>
        <tricky>
            <taxing>3</taxing>
            <mayhem>
                <ohno>4</ohno>
                <boom>5</boom>
            </mayhem>
        </tricky>
    </record>
    <record>
        <first>1</first>
        <second>2</second>
        <tricky>
            <taxing>3</taxing>
            <mayhem>
                <ohno>4</ohno>
                <boom>5</boom>
            </mayhem>
        </tricky>
    </record>
    <record>
        <first>1</first>
        <second>2</second>
        <tricky>
            <taxing>3</taxing>
            <mayhem>
                <ohno>4</ohno>
                <boom>5</boom>
            </mayhem>
        </tricky>
    </record>
</root>

每行记录一行，丢弃记录中的复杂结构。

1,2,3,4,5
1,2,3,4,5
1,2,3,4,5

使用此XSLT

<?xml version="1.0" ?>
<xsl:stylesheet version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   xmlns:p="http://pretend.namespace">

<xsl:strip-space elements="*"/> <!-- remove unwanted whitespace? -->

 <!-- Match every p:record -->
<xsl:template match="p:record">
    <xsl:apply-templates/> <!-- now we're inside a <record> do what you can with the contents then give a line return -->
    <xsl:text>&#xA;</xsl:text><!-- this is a line return -->
</xsl:template>

<xsl:template match="p:record//*">
    <xsl:value-of select="."></xsl:value-of><xsl:text>,</xsl:text>
</xsl:template>

<xsl:template match="text()"/> <!-- WORKS: prevents "default output" to aid debugging -->

</xsl:stylesheet>

但是尽管经过几个小时的尝试，我无法让它访问每个后代并逗号将它们全部分开，我明白了：

1,2,345,
1,2,345,
1,2,345,

我需要做些什么才能让所有的孙子孙女分别对待？（每行的最后一个逗号不是问题）

谢谢！

编辑：此问题之后的讨论表明，Herong Yang博士的Notepad ++ XML工具出现仅支持XSLT 1.0

Answer 1

为什么不简单

<xsl:strip-space elements="*"/>
<xsl:template match="record">
  <xsl:value-of select="descendant::text()/data()" separator=","/>
  <xsl:text>&#xa;</xsl:text>
</xsl:template>

（需要使用data()进行显式雾化，否则，相邻的文本节点会在没有分隔符的情况下连接起来。）

Answer 2

怎么样：

XSLT 1.0

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:p="http://pretend.namespace">
<xsl:output method="text" encoding="utf-8" />
<xsl:strip-space elements="*"/>

<xsl:template match="p:record">
    <xsl:apply-templates/>
    <xsl:text>&#xA;</xsl:text>
</xsl:template>

<xsl:template match="*[not(*)]">
    <xsl:value-of select="."/>
    <xsl:if test="position()!=last()">
        <xsl:text>,</xsl:text>
    </xsl:if>
</xsl:template>

</xsl:stylesheet>

XSLT：我如何单独匹配每个后代？

2 个答案: